// Persistence of Vision Ray Tracer Scene Description File
// File: watergam.pov
// Vers: 3.1
// Desc: Modell of a little fontain     
// Date: 2000/01/08 
// Auth: ReVerSi (reinhard.rettelbach.KH@t-online.de)


// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "skies.inc"


global_settings
{
  assumed_gamma 1.0
  max_trace_level 50
  number_of_waves 50
}

// ----------------------------------------
camera
{
  location  <0, 3.5, -5.0>
  direction 1.3*z
  right     4/3*x
  look_at   <0.0, 0.0,  0.0>
}

sky_sphere{S_Cloud2 }

light_source
{
  0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate <-30, 30, -30>
}


union{
       plane{-(x+z), -10}
       plane{x-z, -10}
                pigment{ rgb <0.85, 0.85, 0.95>}
                finish{reflection 0.85 reflect_metallic}
}


//declaration of functions
#declare TH = function{"TH"}
#declare SPHEROUT = function{x^2+y^2+z^2-2}
#declare SPHERINN = function{x^2+y^2+z^2-1.99}
#declare SPHER = function{SPHEROUT(x, y, z)*SPHERINN(x, y, z)}



 

isosurface{
        function{SPHER(x/1.5, y*(1+0.008*cos(TH*60)), z/1.5)-((y-2)/1.45)^4*noise3d(8*x, y/3, 8*z)}
                bounded_by{ box{<-3, 0, -3>, <3, 15, 3>}}
                threshold .11
                accuracy 0.1
                max_gradient 1.5 method 1  
                hollow
                pigment{ rgbf <1, 1, 1.05, 0.95>}        
                finish {specular 0.15 roughness 0.02 
                        reflection_min 0.1 reflection_max 0.2 reflection_falloff 2}
                interior {ior 1.05}
                }     


difference{
        box{<-15, -5, -10>, <15, 1, 10>}
        box{<-8, -4, -8>, <8, 1.001, 8>}
        pigment{agate color_map{
                [0 rgb <0.8, 0.85, 0.95>]
                [1 rgb <0.6, 0.95, 0.85>]}
                turbulence <1, 0.2, 0.1> }
}
box{-15, <15, 0.15, 15>
        hollow
        pigment{rgbf <1,1,1.05,1>}
        normal{waves 0.55 scale 0.2 turbulence 2}
        finish {specular 0.15 roughness 0.02 
                reflection_min 0.1 reflection_max 0.3 reflection_falloff 2}
        interior {ior 1.05}
} 


//some small "fishes" Do'nt care too much to details, since they will get distorted anyway.
#declare Fish =
        union{sphere{0, 0.5
                scale<1, 0.8, 0.05>}
              difference{
                sphere{0, 0.5}
                sphere{<0.4, 0, 0>, 0.35}
                scale<0.3, 0.6, 0.02>
                translate<0.55, 0, 0>}
              pigment{ rgb <0.8, 0.35, 0.2>*1.2}
              normal{ bumps 0.1 scale 0.1}
              finish{ specular 0.2 roughness 0.01}
        }   
        
object {Fish
        rotate<0, 175, 0>        
        translate <1.5, -.5, -1.4>}
object {Fish
        rotate<0, 20, -5>
        translate <-1, -1, 0.2>}
object {Fish
        rotate <0, -30, 0>
        translate <1, -1.5, 0.5>}
       
union{       
        sphere{0, 0.6
                scale <1, 0.1, 1>
                translate <0, 1.57, 0>}
        cylinder{<0, -12, 0>, <0, 1.5, 0>, 0.2}
        pigment{ rgb <0.8, 0.75, 0.55>*.7}
        finish{specular 0.35 roughness 0.001 reflection 0.2
                }      
        }