// POV users
#include "namelist.inc"
#include "colors.inc"
#include "stones.inc"
#include "metals.inc"
#include "macros.inc"
#include "malachit.inc"
#include "woods.inc"
#include "glass.inc"

camera { location <0,38,-50> look_at <0,-15,0> }
light_source { <-100,200,-300> Gray60 }
light_source { <300,200,-500> Gray60 }
light_source { <-100,300,10> Gray50 }

//                               \/----== TABLE ==---\/
union {
   intersection {
      merge {
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <-6,0,-10> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <-6,0,-50> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <-6,0,30> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <0,0,5> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <6,0,15> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <6,0,-25> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <12,0,30> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <12,0,-10> }
         box { <-3,-2,-20>,<3,-1,20> texture { T_Wood34 scale 2.5 } translate <0,0,-35> }
         rotate 90*y scale <.8,1,.8> translate .7*y
      }
      object { roundbox(-10,-5,-100,100,.701,9*.8+.001,.5) }
      translate -5*x
   }
   object { roundbox (-14.5,-.299,-100,100,0,9*.8-.5,.05) texture { T_Glass3 } interior { I_Glass } }
   scale 10 translate <0,-16.9665,60>
}

//                               \/---== DISK ==---\/
difference {
   object { roundcylinder(3,33,.4) texture { MalachitePolished scale 3 } translate -2*y }
   intersection {
      height_field { png "zodsun.png" scale <20,.5,20> translate <-10,.51,-10> smooth inverse }
      box { <-9.99,.52,-9.99>,<9.99,10,9.99> }
      texture { T_Gold_3B }
   }
   height_field { png "nameshf.png" scale <68,-.2,68> translate <-34,1.01,-34> smooth texture { T_Gold_3B } }
   translate .5*y
}

//                              \/---== "FEET" ==---\/
#declare holdert=difference {
   object { roundcylinder(3,3.5,.4) }
   box { <-1,-1,-1.5>,<4,4,1.5> }
   intersection {
      merge {
         intersection {
            torus { .4,.4 translate <-1,.4,-1.5> }
            box { <-1,-2,-1.5>,<-2,5,-5> }
         }
         intersection {
            torus { .4,.4 translate <-1,.4,1.5> }
            box { <-1,-2,1.5>,<-2,5,5> }
         }
         cylinder { <-1.4,.4,1.6>,<-1.4,.4,-1.6>,.4 }
         cylinder { <-1.1,.4,-1.9>,<5,.4,-1.9>,.4 }
         cylinder { <-1.1,.4,1.9>,<5,.4,1.9>,.4 }
         inverse
      }
      intersection {
         object { roundbox(-1.4,-2,-1.9,4,6,1.9,.4) }
         plane { y,.4 }
      }
   }
   intersection {
      merge {
         intersection {
            torus { .4,.4 translate <-1,2.6,-1.5> }
            box { <-1,-2,-1.5>,<-2,5,-5> }
         }
         intersection {
            torus { .4,.4 translate <-1,2.6,1.5> }
            box { <-1,-2,1.5>,<-2,5,5> }
         }
         cylinder { <-1.4,2.6,1.6>,<-1.4,2.6,-1.6>,.4 }
         cylinder { <-1.1,2.6,-1.9>,<5,2.6,-1.9>,.4 }
         cylinder { <-1.1,2.6,1.9>,<5,2.6,1.9>,.4 }
         inverse
      }
      intersection {
         object { roundbox(-1.4,-2,-1.9,4,6,1.9,.4) }
         plane { -y,-2.6 }
      }
   }
   intersection {
      merge {
         cylinder { <2.44949,.4,1.9>,<2.44949,2.6,1.9>,.4 }
         sphere { <2.44949,.4,1.9>,.4 }
         sphere { <2.44949,2.6,1.9>,.4 }
         inverse
      }
      plane { -x,-2.44949 translate 1.9*z }
      plane { z,0 rotate -37.7997*y translate <2.44949,0,1.9> }
      plane { -z,0 }
   }
   intersection {
      merge {
         cylinder { <2.44949,.4,-1.9>,<2.44949,2.6,-1.9>,.4 }
         sphere { <2.44949,.4,-1.9>,.4 }
         sphere { <2.44949,2.6,-1.9>,.4 }
         inverse
      }
      plane { -x,-2.44949 translate -1.9*z }
      plane { -z,0 rotate 37.7997*y translate <2.44949,0,-1.9> }
      plane { z,0 }
   }
   rotate 90*x translate -1.5*z
}
#declare holder=merge {
   object { holdert }
   intersection {
      torus { 5,1.5 rotate 90*x translate -5*y }
      plane { x,0 rotate -16.6*z translate -5*y }
      plane { x,0 rotate 20*z translate -5*y }
   }
   intersection {
      torus { 2,1.5 rotate 90*x translate <-2,-11.7082,0> }
      plane { -x,0 rotate -16.6*x translate <-2,-11.7082,0> }
      plane { -y,0 translate <-2,-11.7082,0> }
   }
   difference {
      cone { <0,-16.9665,0>,0 <0,-11.7082,0>,2.2 }
      torus { 2.2,.7 translate -11.7082*y }
   }
   intersection {
      sphere { <0,-16.9665,0>,5 }
      plane { -y,16.9665 }
   }
}

object { holder translate -32*x rotate 0*y texture { T_Gold_3A } }
object { holder translate -32*x rotate 60*y texture { T_Gold_3A } }
object { holder translate -32*x rotate 120*y texture { T_Gold_3A } }
object { holder translate -32*x rotate 180*y texture { T_Gold_3A } }
object { holder translate -32*x rotate 240*y texture { T_Gold_3A } }
object { holder translate -32*x rotate 300*y texture { T_Gold_3A } }