// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "skies.inc" 

camera
{
  location  <0.0 , 2.0 ,-7.50>
  look_at   <0.0 , 0.0 , 0.0>
}


// create a regular point light source
light_source
{
  0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate <-20, 10, -20>
}

// An area light (creates soft shadows)
// WARNING: This special light can significantly slow down rendering times!
light_source
{
  0*x // light's position (translated below)
  color rgb 1.0*0.65  // light's color
  // <widthVector> <heightVector> nLightsWide mLightsHigh
  area_light
  <8, 0, 0> <0, 0, 8> // lights spread out across this distance (x * z)
  3, 3                // total number of lights in grid (4x*4z = 16 lights)
  adaptive 0          // 0,1,2,3... 
  jitter         // adds random softening of light
  translate <-10, 60, -20>   // <x y z> position of light
}

   


#declare Sinus = function{sin(x)-z}

sky_sphere{S_Cloud2 rotate<0, 50, 0>}
plane{y, -4.3  pigment{ rgb<0.3, 0.85, 0.1>}
                }

cylinder{<0, -10, 0>, <0, 10, 0>, 7 open hollow inverse no_shadow
        clipped_by{plane{-z, 0}}
        pigment{ rgb <0.7, 0.7, 0.9>}
        normal {wrinkles 0.4}
        finish {specular 0.3 roughness 0.5 reflection 0.2}
        }
        

#declare LEO = function{
                        pigment{leopard color_map{
                                [0 rgb 0]
                                [1 rgb 1]}
                                sine_wave }
                                }                                
                                
 
#declare CON = function{x^2+z^2-(y-3)^2+3}


        
        
isosurface{
        function{CON((x+0.1*LEO(1.5*x, 1, 1.5*z)), y, (z+0.1*LEO(1.5*x, 1, 1.5*z)))-1.35*abs(LEO(3.5*x, 0.2*noise3d(8*x, 1, 8*z), 4.5*z))}
        threshold 0.01
        accuracy 0.01
        max_gradient 100   
        bounded_by{box{-4, 4}} hollow  
        pigment{ rgbf <1, 0.9, 0.7, 0.65>}
        finish{specular 0.35 roughness 0.007}
        interior {ior 1.075}
        scale<1.2, 1.5, 1.2>}  
                                  

#declare POV = text{ttf "C:\windows\fonts\arial.ttf" "PoV-" 0.5, 0}
#declare RAY = text{ttf "C:\windows\fonts\arial.ttf" "Ray" 0.5, 0}

#declare Xdiff = max_extent(POV) - max_extent(RAY);
#declare Yshift = max_extent(RAY);        

#declare POVRAY =
        union{
                object{POV translate <-Xdiff.x/2, Yshift.y+0.25, 0>}
                object{RAY}
                }
                

object{POVRAY
        translate -max_extent(POVRAY)/2
        scale 1.4
        rotate <15, 0, 0>  translate <0, -0.5, -0.5>
        pigment{gradient x+y color_map{
                        [0 rgb <0.9, 0.2, 0.1>]
                        [0.5 rgb <0.7, 0.9, 0.1>]
                        [1 rgb <0.9, 0.2, 0.1>]}
                        scale 2 translate (x+y)}
                        finish {ambient 0.65}
                        }