// clouds.pov
// anthony bennett
// is media ready for clouds yet?
// begun
// 16-11-1999
// finished
// 23-11-1999
// you may freely use and modify the code
// as long as you mention me. thank you.

//declares
#declare SkyBlue = rgb <50,153,204>/255;
#declare ScatCol = 0.001;
#declare Loca = <0,2,-25>;
#declare Look = <5,10,25>;
#declare Luz1 = <-3,6,10>*10000;
#declare Luz2 = y*30000;

//textures
#declare K = color_map {[0 rgb 0][.5 rgb 0][.6 rgb 1][1 rgb 1]}
#declare Clouds =
material {
 texture {pigment {rgbf 1}} interior {media {
 method 3 jitter 0.0 intervals 1 samples 9,9 aa_level 4 aa_threshold .1
 scattering {2, rgb ScatCol/4.25 extinction 1.5} absorption rgb ScatCol/5
 density {bozo octaves 9 lambda 3 turbulence 4 scale 15500*<3,3,4>/3 color_map {K}}
}}}

//background
sky_sphere {pigment {SkyBlue}}
//atmosphere
fog {distance 950 rgbf <7,9,10,.25>/10 fog_type 2 fog_offset 300 fog_alt 1 turbulence .75}
//camera
camera {right x*3/2 up y location Loca look_at Look rotate -x*5}
//sun+fill lights
light_source {Luz1 <9,9,8>/9}
light_source {Luz2 1}
//clouds
box {<50,1,50>*2000,-<10,0,10>*10000 hollow material {Clouds} translate y*6000}