// Note: Unusual use of ior in the brick pattern. 
  //       Turn it off see what happens.


  light_source { <0,0,-30> color rgb 1 }

  camera { location <0,0,-85> }


  // for checker pattern
  #declare Density1 = density { boxed     color_map { [0 rgb<0.0,0.0,2.0>] } }
  #declare Density2 = density { boxed     color_map { [0 rgb<0.0,0.0,0.0>] } }

  // for brick pattern
  #declare Density3 = density { boxed     color_map { [0 rgb<1.5,0.5,0.0>] } }
  #declare Density4 = density { boxed     color_map { [0 rgb<0.0,0.0,0.0>] } }

  // for hexagon pattern
  #declare Density5 = density { spherical color_map { [0 rgb<0.0,1.0,0.0>] } }
  #declare Density6 = density { spherical color_map { [0 rgb<0.0,0.0,2.0>] } }
  #declare Density7 = density { spherical color_map { [0 rgb<2.0,0.0,0.0>] } }


  // The following 5 densities are for the 2 media's 1 using absorsion
  // and  1 using emmission in a checker pattern
  #declare Density8 = 
    density {
     boxed 
      color_map {
       [0.5 rgb<2.00,2.00,2.00>]
       [1.0 rgb<0.00,0.00,0.00>]
      }
    }

  #declare Density9 = 
    density { 
     boxed
      color_map {
       [0.5 rgb<0.00,0.00,0.00>]
       [1.0 rgb<2.00,2.00,2.00>]
      }
    }

  // A dummy density For balancing the two groups
  #declare Density10 = 
    density { 
     boxed 
      color_map {
       [0 rgb<2.0,2.0,2.0>]
      }
    }

  #declare Density11 = 
    density {
     boxed
      sine_wave
       density_map {
        [0.5 Density8  scale 0.5]
        [0.5 Density10 scale 0.5]
       }  
    }

  #declare Density12 = 
    density {
     boxed
      sine_wave
       density_map {
        [0.5 Density9  scale 0.5]
        [0.5 Density10 scale 0.5]
       }
    }



  // Checker Pattern Object Upper Left
  #declare Media1 =
  box { -1,1
   pigment {
    rgbt<1,1,1,1>
   }
     finish {
      ambient 0 
      diffuse 0
     }
         interior {
           media{
               emission   0.0200
               intervals 15.0000 
               samples    5.0000, 25.0
               confidence 0.9999
               variance   0.0001

        density {
         checker
           density{
             Density1
              scale 0.5
           }
          density{
            Density2
             scale 0.5
          }
         translate -0.5
        scale 1}
       }
      }
     hollow
    }


  // Brick Pattern Object Upper Right
  #declare Media2 =
   box { -1,1
    pigment {
     rgbt<1,1,1,1>
    }
     finish {
      ambient 0 
      diffuse 0
     }
         interior { ior 1.5 // Note use of ior here
             media {
               emission   0.0200
               intervals 15.0000 
               samples    5.0000, 25.0
               confidence 0.9999
               variance   0.0001
         
          density {
            brick
              density {
                Density4 
                 scale 1
              }
              density {
                Density3
                 scale 1
              }
             translate -0.5
            scale 0.4
           }
          }
         }
        hollow
       }


   // Hexagon Pattern Object Lower Left
   #declare Media3 =
    box { -1,1
     pigment {
      rgbft<1,1,1,1>
     }
      finish {
       ambient 0 
       diffuse 0
      }
         interior {
             media {
               emission   0.0200
               intervals 15.0000
               samples    5.0000, 25.0
               confidence 0.9999
               variance   0.0001
         
          density {
            hexagon
              density {
                Density5 
               scale 1
              }
              density {
                Density6
               scale 1
              }
              density {
                Density7
               scale 1
              }
             translate -0.5
            scale 0.5
           rotate 90*x
          }
         }
        }
       hollow
      }


  // Checker Pattern Object Lower Right
  #declare Media4 =
  box { -1,1
   pigment {
    rgbt<1,1,1,1>
   }
     finish {
      ambient 0 
      diffuse 0
     }
         interior {
             media {
               emission   0.0200
               intervals 15.0000 
               samples    5.0000, 25.00
               confidence 0.9999
               variance   0.0001

     density {
         checker
          density {
            Density8
           scale 0.25 
          }
          density {
            Density9 
           scale 0.25 
          }
         translate -.25
        scale .5
       }
      }

             media {
               absorption rgb 2
               intervals 15.0000 
               samples    5.0000, 25.0
               confidence 0.9999
               variance   0.0001

     density {
         checker
          density {
            Density9
           scale 0.25
          }
          density {
            Density8 
           scale 0.25
          }
         translate -.25
        scale .5
       }
      }
     }
   hollow
  }



  object { Media1 scale <15,15,15> translate <-16, 16,0> }
  object { Media2 scale <15,15,15> translate < 16, 16,0> }
  object { Media3 scale <15,15,15> translate <-16,-16,0> }
  object { Media4 scale <15,15,15> translate < 16,-16,0> }


  plane { -z, -40 pigment { rgb .3 } finish { ambient .25 diffuse .25 } }