global_settings { assumed_gamma 2.2 }
global_settings { max_trace_level 20}

// THESE THREE DECLARATIONS WILL BE USED TO MAKE IT EASIER
// TO KEEP TRACK OF YOUR GRAYSCALE COLORS
#declare Red2= 0.299;
#declare Green2= 0.587;
#declare Blue2= 0.114;

#declare Moire=
 texture {
  pigment {
   bozo
   turbulence 0.7
   color_map {
    [0.00 rgb<0.34,0.1,0.64>]
    [0.32 rgb<0.34,0.30,0.0>]
    [0.80 rgb<0.21,0.67,0.67>]
   }
  }
  normal {granite 0.2 turbulence 0.8 scale <1,30,1>}
  finish {specular 0.1 roughness 0.1}
 }

// MOIRE2 IS THE GRAYSCALE VERSION OF MOIRE.
// BASICALLY, INSTEAD OF rgb<#,#,#> YOU DO AN
// rgb (Red2*#+Green2*#+Blue2*#)
#declare Moire2=
 texture {
  pigment {
   bozo
   turbulence 0.7
   color_map {
    [0.00 rgb (Red2*0.34+Green2*0.1+Blue2*0.64)]
    [0.32 rgb (Red2*0.34+Green2*0.30+Blue2*0.0)]
    [0.80 rgb (Red2*0.21+Green2*0.67+Blue2*0.67)]
   }
  }
  normal {granite 0.2 turbulence 0.8 scale <1,30,1>}
  finish {specular 0.1 roughness 0.1}
 }

#declare BWRed=
 texture { 
  pigment {
   marble
   color_map {
    [0.00 Red]
    [0.49 Red]
    [0.51 rgb 0.299]
    [1.00 rgb 0.299]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.03}
 }

#declare BWGreen=
 texture {
  pigment {
   marble
   color_map {
    [0.00 Green]
    [0.49 Green]
    [0.51 rgb 0.587]
    [1.00 rgb 0.587]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.03}
 }

#declare BWBlue=
 texture {
  pigment {
   marble
   color_map {
    [0.00 Blue]
    [0.49 Blue]
    [0.51 rgb 0.114]
    [1.00 rgb 0.114]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.03}
 }

#declare BWViolet=
 texture {
  pigment {
   marble
   color_map {
    [0.00 rgb<1,0,1>]
    [0.49 rgb<1,0,1>]
    [0.51 rgb Red2+Blue2]
    [1.00 rgb Red2+Blue2]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.008 reflection 0.34}
 }

#declare BWTurquoise=
 texture {
  pigment {
   marble
   color_map {
    [0.00 rgb<0,1,1>]
    [0.49 rgb<0,1,1>]
    [0.51 rgb Green2+Blue2]
    [1.00 rgb Green2+Blue2]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.008 reflection 0.34}
 }

#declare BWYellow=
 texture {
  pigment {
   marble
   color_map {
    [0.00 rgb<1,1,0>]
    [0.49 rgb<1,1,0>]
    [0.51 rgb Red2+Green2]
    [1.00 rgb Red2+Green2]
   }
   translate -0.25*x
   scale 40
  }
  finish {specular 0.8 roughness 0.008 reflection 0.34}
 }

camera {
  location <0, 1, -5>
  direction <0, 0, 1>
  up  <0, 1, 0>
  right <4/3, 0, 0>
  look_at <0, 1, 0>
}

// COMMENT OUT THE AREA LIGHT PORTIONS UNTIL YOU'RE READY FOR
// THE LONG, LONG FULLSCALE RENDER
light_source { <-8, 15, -10> color rgb 0.4 
 area_light <-12, 9, -14>, <-4, 1, -6>, 6, 6
 adaptive 3
 fade_distance 50
 fade_power 20
}
light_source { <8, 15, -10> color rgb 0.4 
 area_light <-12, 9, -14>, <-4, 1, -6>, 6, 6
 adaptive 3
 fade_distance 50
 fade_power 20
}


superellipsoid {<0.42,0.42>
 scale <60,30,30>
 translate <0,30,10> 
 texture {
  marble
  texture_map {
   [0.00 Moire scale 3/80]
   [0.49 Moire scale 3/80]
   [0.51 Moire2 scale 3/80]
   [1.00 Moire2 scale 3/80]
  }
  translate -0.25*x
  scale 80
 }
}

sphere {0,3 
 translate <0,0.5,4> 
 rotate -45*x 
 rotate 75*y 
 translate <-2,0,10>
 texture {BWRed}
}

torus {3.5,0.5 
 translate <0,0.5,4> 
 rotate -45*x 
 rotate 75*y 
 translate <-2,0,10>
 texture {BWGreen}
}

cone {<0,0,0>,1.5,<0,-4.6,0>,0
 translate <0,0.5,4> 
 rotate -45*x 
 rotate 75*y 
 translate <-2,0,10>
 texture {BWBlue}
}

cone {<0,0,0>,1.5,<0,4.6,0>,0
 translate <0,0.5,4> 
 rotate -45*x 
 rotate 75*y 
 translate <-2,0,10>
 texture {BWBlue}
}

sphere {0,1
 translate <0,1.001,4>
 texture {BWYellow}
}

sphere {0,1
 scale <2,0.2,0.5>
 translate <0,0.201,1.5>
 texture {BWTurquoise}
}

sphere {0,1
 scale <2,0.1,0.25>
 translate <0,0.101,0.25>
 texture {BWViolet}
}