//A simplified version of Anthony Bennett's
//spiral-sphere. To be used, abused and
//enjoyed, with credit when credit is due...
//(ie: when your tinkering with this is minimal)

default {finish {ambient .5}}

#declare R = 10;     //radius of the sphere

#declare M = pi/5;   //my 'magic number'

#declare Max = 360;  //use 360 for a full sphere

#declare A=-25;      //what angle to begin
                     //creating the sphere from

camera
{
 location <1,1,-2>*R
 look_at 0
}

light_source {<1,1,-1>*R*3 1}

union
{
 #while (A<Max)
  
  #declare P11=A/2;
  #declare P12=(A+M*25)/2;
  #declare P13=(A+M*26)/2;
  
  #declare P21=(A-M)/2;
  #declare P22=P11;
  #declare P23=P12;
  
  sphere
  {
   0,.2
   pigment {rgb <1,sin(radians(P11)),0>}
   translate y*R
   rotate <P11,P11*45,0>
  }
  
  triangle
  {
   vrotate(y*R,<P11,P11*45,0>), //replace with 0 (interesting...)
   vrotate(y*R,<P12,P12*45,0>),
   vrotate(y*R,<P13,P13*45,0>)
   pigment {rgb <0,.5,1>}
  }
  
  triangle
  {
   vrotate(y*R,<P21,P21*45,0>), //replace with 0 (interesting...)
   vrotate(y*R,<P22,P22*45,0>),
   vrotate(y*R,<P23,P23*45,0>)
   pigment {rgb <0,1,.5>}
  }
  
  #declare A=A+M;
 #end
}