// A speed comparison test between multiple media vs. multiple containers
// By Peter Popov
// peter.popov@usa.net
// ICQ 15002700

#declare Type = 2;
#declare Particles = 50; // int(99*clock)+1;

#declare Seed1 = seed (42);
#declare Seed2 = seed (1980);

#global_settings { max_trace_level Particles*2 max_intersections Particles*2 }

#declare Black  = color rgb <0,0,0>;
#declare Red    = color rgb <1,0,0>;
#declare Yellow = color rgb <1,1,0>;
#declare White  = color rgb <1,1,1>;

#declare MediaQ = 1 + 4*clock; 

// 1 - horrible 4 - medium  6 - high 8 - Very high 10 - overkill (type 1)
// 1 - low 2 - medium  3 - high 4 - Very high 5 - overkill (type 2)

#declare SamplesLow = 1+MediaQ/5;
#declare SamplesHigh = int(pow(MediaQ, 1.5))+1; 
#declare Intervals = int(pow(MediaQ, 1.5));

#debug concat("\nsamples ", str(SamplesLow,0,0),", ",str(SamplesHigh,0,0))
#debug concat("\nintervals ", str(Intervals,0,0),"\n")

#switch (Type)
  #case (1)
    sphere
    {
      0, 1
      pigment { rgbf 1 }
      hollow
      interior
      {
        #declare i=0;
        #while (i<Particles)
          #declare Rad=(0.1+0.9*rand(Seed1))/2;
          media
          {
            samples SamplesLow, SamplesHigh
            intervals Intervals
            confidence 0.999999
            variance 1/1024
            emission 2/pow(Particles,0.5)
            density
            {
              spherical
              color_map { [0 Black][0.25 Red][0.75 Yellow][1 White] }
              scale Rad
              translate <2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad))>
            }
          }
          #declare i=i+1;
        #end
      }
    }
  #break

  #case (2)
    #declare i=0;
    #while (i<Particles)
      #declare Rad=rand(Seed1)/2;
      sphere
      {
        0, 1
        pigment { rgbf 1 }
        hollow
        interior
        {
            media
            {
              samples SamplesLow, SamplesHigh
              intervals Intervals
              confidence 0.999999
              variance 1/1024
              emission 2/pow(Particles,0.5)
              density { spherical color_map { [0 Black][0.25 Red][0.75 Yellow][1 White] } }
            }
        }
        scale Rad
        translate <2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad))>
      }
      #declare i=i+1;
    #end
  #break

  #case (3)
  merge
  {
    #declare i=0;
    #while (i<Particles)
      #declare Rad=rand(Seed1)/2;
      sphere { 0, Rad translate <2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad))> }
      #declare i=i+1;
    #end

    #declare Seed1 = seed (42);
    #declare Seed2 = seed (1980);
    
    pigment { rgbf 1 }
    hollow
    
    interior
    {
      #declare i=0;
      #while (i<Particles)
        #declare Rad=(0.1+0.9*rand(Seed1))/2;
        media
        {
          samples SamplesLow, SamplesHigh
          intervals Intervals
          confidence 0.999999
          variance 1/1024
          emission 2/pow(Particles,0.5)
          density
          {
            spherical
            color_map { [0 Black][0.25 Red][0.75 Yellow][1 White] }
            scale Rad
            translate <2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad)),2*((0.5-rand(Seed2))*(1-Rad))>
          }
        }
        #declare i=i+1;
      #end
    }
  }
  
  #break
#end

camera
{
  location  <0.0 , 2.0 ,-5.0>
  up y
  right x
  angle 22.5
  look_at   <0.0 , 0.0 , 0.0>
}