// Render string: +QR +A0.2 +AM2 +R4 +W640 +H480

global_settings {
        assumed_gamma 2.2     
        radiosity {
                count 1200              // I am aware that the radiosity
                error_bound 0.33        // settings are completely overkill.
                gray_threshold 0.5      // But I was asked for the source that
                distance_maximum 4      // produced the picture, sooo...
                low_error_factor 0.33   // I would think that raising the global
                nearest_count 9         // ambience of the scene, would produce
                minimum_reuse 0.01      // a nicer image.
                brightness 3.3          // -
                recursion_limit 2       // PS. Sorry about the messy source, no time to clean up.
        }
}
    
#include "colors.inc"

#default { finish { ambient 0.5 diffuse 0.65 } }

#declare w = 2;
#declare h = 2;
#declare T = 0.05;

#declare Lx = -0.8;
#declare Ly = ((h-T)/10)*9;
#declare Lz = -0.8;

#declare Wall = texture {
                        pigment {
                                color <1.0, 1.0, 0.9>
                        }
                        finish  {
                                diffuse 0.4
                        }
                }

#declare SoftTeal   = texture {
                        pigment {
                                color <0.2, 1.0, 0.8>
                        }
                        finish  {
                                diffuse 0.7
                        }
                }

#declare SoftBlue   = texture {
                        pigment {
                                color <0.2, 0.6, 1.0>
                        }
                        finish  {
                                diffuse 0.7
                        }
                }

#declare Bulp = object {
                        sphere {
                                <0,0,0> 0.05
                                texture {
                                        pigment {
                                                color White
                                        }
                                }
                        }
                }
                
camera {
        location  <0.6, 0.9, 0.8>
        look_at   <0.0, 0.5, 0.0>
        panoramic
        angle 15  
}

light_source {
                <Lx, Ly, Lz>
                color White
                looks_like {
                        Bulp
                }
                area_light 0.5*x, 0.5*y, 7,7
                adaptive 1
                jitter
}

difference {
        box {
                <-w/2, 0, w>, <w/2, h, -w/2>
        }

        box {
                <(-w/2)+T, T, w-T>, <(w/2)-T, h-T, (-w/2)+T>
        }
        texture { Wall }
}

plane {
        y, T
        texture {
                pigment {
                        White
                }
                finish  {
                        diffuse 0.8
                }
        }
}

plane {
        x, (w/2)-T
        texture {
                pigment {
                        Orange
                }
                finish  {
                        diffuse 0.8
                }
        }
}

plane {
        z, (-w/2)+T
        texture {
                pigment {
                        Red
                }
                finish  {
                        diffuse 0.8
                }
        }
}

plane {
        z, (w/2)-T
        texture {
                pigment {
                        White
                }
                finish  {
                        diffuse 0.8
                }
        }
}


difference {
        box {
                <-0.25, T, 0.25>, <0.25, T+0.5, -0.25>
                texture {
                        Wall
                }
        }
        box {
                <-0.25, T, 0.25>, <0.25, T+0.5, -0.25>
                translate <T,-T, T>
                texture {
                        SoftTeal
                }
        }
        scale 2
        translate (T*2)*-y
}

sphere {
        <0, T+0.3, 0>, 0.3
        texture {
                SoftBlue
        }
}