#include "colors.inc"
#include "woods.inc"

global_settings { assumed_gamma 2.3 }

//#declare Glass=
difference
{
  union
  {
    intersection
    {
      superellipsoid { <1, 0.5> rotate 90*x translate 0.5*y scale <3.1,1.2,3.1> }
      union
      {
        cone { 0*y, 2.7, 0.3*y, 3 }
        cone { 1.2*y, 3, 1.5*y, 2.7 }
        intersection
        { plane { -y, 0.3 }
          plane { y, 1.5 }
          #declare i=0;
          #while (i<12)
            plane { x, 3 rotate y*30*i }
            #declare i=i+1;
          #end
        }
      }
    }
  
    cylinder { 1.5*y, 6*y, 2.7 }
    cylinder { 6*y, 7.2*y, 3 }
    torus { 2.7, 0.3 translate 6*y }
    torus { 2.85, 0.15 scale <1,0.5,1> translate 7.2*y }
    
    #declare j=-1;
    #while (j<9)
      #declare i=0;
      #while (i<20)
        superellipsoid 
        { <0.25, 1.75>
          rotate 90*x
          rotate 45*y
          scale 0.3
          scale <0.6,1,1>
          translate <2.68725,1.9+j*0.4,0>
          rotate i*18*y+9*mod(j,2)*y
        }
        #declare i=i+1;
      #end
      #declare j=j+1;
    #end
  }
  
  cylinder { 0.5*y, 7.3*y, 2.35 }
  cone { 6*y, 2.35, 7.200001*y, 2.7 }
  
  bounded_by { cylinder { 0, 7.2001*y, 3.001 } }
  
  texture 
  { 
    pigment { rgb <0.85,0.95,1> filter 0.95} 
    finish 
    { 
      specular 0.25
      roughness 0.0025
      phong 0.35
      phong_size 10
      metallic 0.25
      diffuse 0.1
      ambient 0.9
    }
  }
  interior { ior 1.45 fade_power 2 fade_distance 25}
  translate 0.0001*y
}

plane {
  y,0
  texture{ T_Wood34 finish { diffuse 2 } scale 3 rotate <-1,40,0> translate 50 }
}


light_source 
{ <100,45,-100>
  color White 
//  area_light 20*x, 20*y, 3, 3 adaptive 0
  spotlight 
  point_at 
  0 
  radius 1 
  falloff 4
  tightness 30
  rotate 20*y
}

camera { location < 2, 15, -25> angle 30 right x look_at 3.6*y }