/*
 POV-Ray 3.1e demonstration of
 CRC Standard surface 9.4.4 4 given on page 298
 of CRC Standard Curves & Surfaces; CRC press 1993
 <davidwilkinson@cwcom.net>
 
It uses P_surfa.inc by David Sharp <dsharp@interport.net>
*/

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

global_settings { max_trace_level 7 }

#declare uusteps = 40;	
#declare vvsteps = 40;	
#declare vvmin   = -1;
#declare vvmax   =  1;
#declare uumin   = -1;
#declare uumax   =  1;

#declare a1=1.5;
#declare b1=1;
#declare c1=0.4;

#macro Zvalue (u1,v1)
 c1*sin(2*pi*b1*u1)*exp(a1*v1)
#end

#macro xyz(u1,v1)	
    < u1,
     v1,
    Zvalue (u1,v1)>
#end

#declare use_smooth_triangles=1;

#include "p_surfa.inc"
  
object{
	p_surface
	texture{T_Brass_5D}
        rotate 90*x
        rotate 200*y
}

camera
{ 
  location  < -1.5, 2.5,2>
  look_at   < 0.5, -0.25, -0.8>
} 

light_source { <40, 20, -20> color rgb 1 }

sky_sphere{
    pigment {
        bozo
        color_map {
            [ 0.00 rgb < 0.000, 0.000, 0.000 > ]
            [ 0.35 rgb < 0.1, 0.1, 0.25 > ]
            [ 0.65 rgb < 0.400, 0.350, 0.420 > ]
            [ 1.00 rgb < 0.15, 0.150, 0.150 > ]
        }
        turbulence < 0.400, 0.600, 0.200 >
    }
}

plane {z,100 pigment {White} hollow}