//Scene file copyright Andrew Cocker
//You'll need Chris Colefax's Lens Effects include file

#include "colors.inc"
#include "textures.inc"


// camera
camera {
location <0,-1.2,-2.5>
direction 0.75*z
up        y                
right     4/3*x   
look_at <0,-0.3,0>
aperture .1
   focal_point <0, 0, 0>
   blur_samples 300 
   confidence .999999            
    variance 1/500             
}
//
// lights
light_source {
0*x
rgb <1,1,1>
translate <10,10,-10>
}
// modified from Gilles Tran's City.inc
fog {fog_type 2 rgb .4 distance 50 fog_alt 2 turbulence 1}
      sky_sphere {pigment {gradient y pigment_map {
         [0 rgb 1]
         [.1 wrinkles color_map {[.5 rgb 1] [.7 rgb .5]} scale .1]
         [.15 wrinkles color_map {[.1 rgb 1] [.4 rgb .6]} scale .1]
         [.25 rgb .7]}}}

//textures
//

#declare Single_Curve=
union {
#declare r=0.01;
#declare A=10; // number of rods
#declare Count=0; #while (Count<=A)
#declare Horiz=Count; #declare Vert=A-Count;
cylinder {<Horiz/A,0,0>,<0,Vert/A,0>,r  }
#declare Count=Count+1; #end
}

#declare Twelve_Curve=
union {
object {Single_Curve}
object {Single_Curve rotate y*90}
object {Single_Curve rotate y*180}
object {Single_Curve rotate y*270}
object {Single_Curve rotate x*180}
object {Single_Curve rotate x*180 rotate y*90}
object {Single_Curve rotate x*180 rotate y*180}
object {Single_Curve rotate x*180 rotate y*270}
object {Single_Curve rotate x*-90}
object {Single_Curve rotate x*-90 rotate y*90}
object {Single_Curve rotate x*-90 rotate y*180}
object {Single_Curve rotate x*-90 rotate y*270}
}

#declare End_Cone=
cone {<A/10,0,0>,0.01 <(A/10)+0.1,0,0>,r*0.35}

#declare Big_Curve=
union {
object {Twelve_Curve}
object {Twelve_Curve scale .35 translate x*1.35}
object {Twelve_Curve scale .35 translate x*-1.35}
object {Twelve_Curve scale .35 translate z*1.35}
object {Twelve_Curve scale .35 translate z*-1.35}
object {Twelve_Curve scale .35 translate y*1.35}
object {Twelve_Curve scale .35 translate y*-1.35}
object {End_Cone}
object {End_Cone rotate y*90}
object {End_Cone rotate y*180}
object {End_Cone rotate y*270}
object {End_Cone rotate z*90}
object {End_Cone rotate z*-90}
}
 
 
object {Big_Curve texture {pigment {rgb <1,.4,0>}finish {Dull}}
rotate <20,30,20>}

plane {y,-1.6 hollow 
  texture {
  pigment {Tan}
  finish { crand .3 ambient .4}
  normal {crackle 1 scale .1 turbulence .5}
  }}

#declare Tex1=
texture {
  pigment {
       rgb <.8,.7,.6>
      }
      normal { wrinkles .25 turbulence .1}
   finish {Dull}
scale <80,4,80>
scale .001
}
#declare Tex2=
texture {
  pigment {Tan}
  finish { crand .3 ambient .4}
  normal {crackle 1 scale .1 turbulence .5}
 scale <1,.02,1> }
  
union {        
box {<-.2,-1.6,-.2>,<2,95,.2> translate <2,0,2>}
box {<-2,-1.6,-2>,<.2,95,.2>  translate <-14,0,26>}            
box {<-4,-1.6,-4>,<.2,95,.2>  translate <12,0,84>}
texture {
gradient y turbulence 0.005
texture_map {
[0 Tex2]
[0.01 Tex1]
[0.01 Tex1]
[1 Tex1]
}
scale <1,100,1>
translate y*-1.6}

}

//The lens flare

#declare camera_location = < 0, -1.2, -2.5> ; 
#declare camera_look_at = < 0, -0.3, 0> ; 
#declare effect_location = <0,-.25,-.5>;
#declare effect_type="Camera2"
#declare options_only = true; #include "Lens.inc" 
#declare effect_scale=0.55;
#declare effect_always_on_top=false;
#declare spots_contract_to_centre=true;
#declare spots_type=0;
#include "LnsEfcts.inc"