// Alex Kluchikov, 2003
// mailto: klkspa[at]ukr.net, aklk[at]mail.ru
// Feel free to modify/use in any form

sky_sphere{pigment{gradient y color_map{[0,color rgb <0.8,0.83,1>][1,color rgb <0.4,0.7,1>]}scale 2 translate -y}}
sphere{0,1000 texture{
 pigment{average pigment_map{
 #declare gr=.8;
 #declare ge=3/(1+gr+gr);
 #declare t1=.3;
 #declare t2=.8;
 #declare tr1=.1;
 #declare tr2=.1;
  [1,bozo translate 5*y color_map{
   [t1,color rgbt < 1,gr,gr,tr1>*ge]
   [t2,color rgbt < 0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate 5*z color_map{
   [t1,color rgbt < gr, 1,gr,tr1>*ge]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate 5*x color_map{
   [t1,color rgbt < gr,gr, 1,tr1>*ge]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]
   
 }}scale 0.25 finish{ambient 1 diffuse 0}scale 3000}no_shadow no_image 
 hollow double_illuminate scale 100}

#declare st=texture{pigment{color rgb<0.83,0.82,0.84>*1.2}
  finish{diffuse 0.85 ambient 0 specular 0.9 roughness 0.03 phong 1.0 brilliance 7.3 phong_size 80  metallic .5 
   reflection{0.6,1.0 metallic}}
  }

#declare area=1; 
#declare areacount=5;
#declare areasize=5;

light_source{        
 -35*z, color rgb <1.0,0.8,0.6>*0.55
#if(area)           
 area_light x*areasize,y*areasize,areacount,areacount jitter adaptive 1 circular orient 
#else
 parallel
#end
 rotate x*25 rotate -y*65
 }

light_source{
 -35*z, color rgb <0.6,0.8,1>*0.55
#if(area) 
 area_light x*areasize,y*areasize,areacount,areacount jitter adaptive 1 circular orient 
#else
 parallel
#end
 rotate x*35 rotate y*25
 }

light_source{
 -35*z, color rgb 0.2
 parallel
 rotate x*90
 shadowless
 }

camera{
 location -5*z
 look_at 0
 rotate x*45
 }

union{
difference{
 plane{y,0}
 cylinder{y*0.001,y*-1,1}
 }
 torus{1,1 translate -y}
 scale 2.2
 texture{
  pigment{checker color rgb .5 color rgb 1 rotate y*45 translate -y/2 scale .3 scale y*10}
  finish{ambient .2 diffuse 1 phong 2 phong_size 200}
  }
 scale 2
 translate -y*1.3
 translate z*2
 }

sphere{-y*3.6,.6 texture{st}
 translate z*2
 }