// Alex Kluchikov, 2003
// mailto: klkspa@ukr.net, aklk@mail.ru
// ICQ 129514109
// Feel free to modify/use in any form
// Please, notify me, if you found this source useful

sky_sphere{pigment{gradient y color_map{[0,color rgb <0.7,0.75,1>][1,color rgb <0.2,0.5,1>]}scale 2 translate -y}}
sphere{0,1000 texture{pigment{bozo color_map{[0,color rgbt <1,1,1,0.15>][1,color rgbt<0,0,0,0.15>]}}scale 0.25 finish{ambient 0.5 diffuse 0.5}scale 2000}no_shadow no_image double_illuminate}
#declare st=texture{pigment{color rgb<0.83,0.82,0.87>*1}
 finish{diffuse 0.6 ambient 0 specular 0.9 phong 1.1 phong_size 80  metallic 0.5 reflection{0.7,0.9 metallic}}}

#declare pbt=texture{
 pigment{color rgb <0.8,0.85,1>}
 finish{ambient <0.1,0.1,0.12> diffuse 1.0 specular 0 phong 0}
 normal{granite .4 scale 0.3+x*0.6}
 }

#declare pbr=texture{
 pbt rotate -z*90
 }
#declare pbe=texture{
 pbt rotate -z*45
 }
 
camera{
 orthographic
 location -5*z
 look_at 0
// rotate x*35
// rotate y*45
 } 
 
light_source{
 -5*z,color rgb <0.8,0.8,1>*0.8
 parallel
 rotate 30*x
 rotate 45*y
 }

light_source{
 -5*z,color rgb <1,1,0.8>*0.7
 parallel
 rotate 10*x
 rotate -30*y
 }
 

#declare aclock=0;

#declare obj=union{
blob{
 threshold 0.1
//corpse
 sphere{0,1,1 scale <1.35,0.65,0.6>texture{pbt}}
 sphere{0,1,0.8 scale <0.85,0.65,0.7> translate <0.5,0.1,0>texture{pbe}}
 sphere{0,1,0.5 scale <0.6,0.6,0.6> translate <-0.6,0.05,0>texture{pbe}}
//neck transformation
 #declare tneck=transform{
  translate <0.8,-0.18,0>
//------following 2 lines are the neck control
  rotate z*0 // neck up-down     +-70
  rotate y*0 // neck left-right +-70 

  translate -<0.8,-0.18,0>
  }
//neck
 sphere{0,1,1 scale <0.6,0.36,0.36> translate <-1.1,0.16,0>texture{pbt} transform{tneck}}
//head transformation
 #declare thead=transform{
  translate <1.25,-0.27,0>
//------following 2 lines are the head control
  rotate z*0 // head up-down     +- 15
  rotate y*0 // head left-right  +- 20

  translate -<1.25,-0.27,0>
  transform{tneck}
  }
//hears
 sphere{0,1,1 scale <0.27,0.15,0.08> rotate y*55 rotate x*30 translate <-1.52,0.375,-0.14>texture{pbt}transform{thead}}
 sphere{0,1,1 scale <0.27,0.15,0.08> rotate y*55 rotate x*30 translate <-1.52,0.375,-0.14> scale -z texture{pbt}transform{thead}}
//head
 sphere{0,1,1 scale <0.65,0.33,0.35> translate <-1.45,0.27,0>texture{pbt}transform{thead}}
 sphere{0,1,1 scale <0.4,0.19,0.18> translate <-1.8,0.29,0>texture{pbt}transform{thead}}
 sphere{0,1,1 scale <0.3,0.18,0.16> translate <-1.87,0.25,0>texture{pbt}transform{thead}}
 sphere{0,1,1 scale <0.25,0.17,0.15> translate <-1.98,0.26,0>texture{pbt}transform{thead}}
//nose
 sphere{0,1,10 scale <0.09,0.08,0.09> translate <-2.13,0.27,0>texture{pbt pigment{color rgb 0}}transform{thead}}
//eyes
 sphere{0,1,-0.075 scale <0.2,0.2,0.2> translate <-1.8,0.4,-0.16>texture{pbt}transform{thead}}
 sphere{0,1,-0.075 scale <0.2,0.2,0.2> translate <-1.8,0.4,-0.16>texture{pbt} scale -z transform{thead}}

 sphere{0,1,-10 scale <0.075,0.075,0.075> translate <-1.8,0.38,-0.14>texture{pbt}transform{thead}}
 sphere{0,1,-10 scale <0.075,0.075,0.075> translate <-1.8,0.38,-0.14>texture{pbt} scale -z transform{thead}}

 sphere{0,1,-0.1 scale <0.3,0.3,0.3> translate <-1.8,0.35,-0.18>texture{pbe}}
 sphere{0,1,-0.1 scale <0.3,0.3,0.3> translate <-1.8,0.35,-0.18>texture{pbe} scale -z transform{thead}}

//legs
#declare leg01=transform{
 translate -<0.8,0.1,0.26>
// rotate z*90*sin(aclock*2*pi) // Tried to animate, uncomment to get "aerobics dancing" bear
 translate  <0.8,0.1,0.26>
 }
 sphere{0,1,1 scale <0.4,0.7,0.35> translate <0.8,-0.1,0.26>texture{pbr}transform{leg01}scale -z} 
#declare leg01_1=transform{
 translate -<0.9,-0.35,0>
// rotate z*90*abs(sin(aclock*2*pi)) // Tried to animate, uncomment to get "aerobics dancing" bear
 translate <0.9,-0.35,0>
 transform{leg01}
 }
 sphere{0,1,1 scale <0.3,0.5,0.3> translate <0.8,-0.5,0.26>texture{pbr}transform{leg01_1}scale -z} 
 sphere{0,1,1 scale <0.25,0.3,0.25> translate <0.8,-0.85,0.26>texture{pbr}transform{leg01_1}scale -z} 
 sphere{0,1,1 scale <0.3,0.1,0.2> translate <0.7,-1.0,0.26>texture{pbr}transform{leg01_1}scale -z} 

 sphere{0,1,1 scale <0.4,0.7,0.35> translate <0.8,-0.1,0.26>texture{pbr}} 
 sphere{0,1,1 scale <0.3,0.5,0.3> translate <0.8,-0.5,0.26>texture{pbr}} 
 sphere{0,1,1 scale <0.25,0.3,0.25> translate <0.8,-0.85,0.26>texture{pbr}} 
 sphere{0,1,1 scale <0.3,0.1,0.2> translate <0.7,-1.0,0.26>texture{pbr}} 



 sphere{0,1,1 scale <0.35,0.65,0.4> translate <-0.6,-0.175,0.21>texture{pbr}} 
 sphere{0,1,1 scale <0.35,0.65,0.4> translate <-0.6,-0.175,0.21>texture{pbr}scale -z} 
 sphere{0,1,1 scale <0.25 ,0.4,0.25> translate <-0.6,-0.6,0.3>texture{pbr}} 
 sphere{0,1,1 scale <0.25 ,0.4,0.25> translate <-0.6,-0.6,0.3>texture{pbr}scale -z} 
 sphere{0,1,1 scale <0.2 ,0.4,0.2> translate <-0.6,-0.7,0.3>texture{pbr}} 
 sphere{0,1,1 scale <0.2 ,0.4,0.2> translate <-0.6,-0.7,0.3>texture{pbr}scale -z} 

 sphere{0,1,1 scale <0.2 ,0.2,0.2> translate <-0.6,-0.9,0.3>texture{pbr}scale -z} 
 sphere{0,1,1 scale <0.3 ,0.1,0.17> translate <-0.7,-1.0,0.3>texture{pbt}scale -z} 

 sphere{0,1,1 scale <0.2 ,0.2,0.2> translate <-0.6,-0.9,0.3>texture{pbr}} 
 sphere{0,1,1 scale <0.3 ,0.1,0.17> translate <-0.7,-1.0,0.3>texture{pbt}} 
 
 }
 sphere{0,1 scale <0.04,0.03,0.04> translate <-1.78,0.36,-0.12>texture{pigment{color rgb 0} finish{phong 1 phong_size 40}}transform{thead}}
 sphere{0,1 scale <0.04,0.03,0.04> translate <-1.78,0.36,-0.12>texture{pigment{color rgb 0} finish{phong 1 phong_size 40}} scale -z transform{thead}}
} 
 
#declare sc=0.5;

 
object{obj
 scale sc
 rotate y*90
 rotate -x*90
 translate <-2,-1.15>
 }

object{obj
 scale sc
 rotate y*90
 translate <-2,1.15>
 }


object{obj
 scale sc
 rotate -y*90
 translate <0,-1.15>
 }

object{obj
 scale sc
 translate <0,1.15>
 }

object{obj
 scale sc
 rotate y*45
 rotate -x*asin(1/sqrt(3))*180/pi
 translate <2,1.15>
 }
 
object{obj
 scale sc
 rotate y*-45
 rotate -x*asin(1/sqrt(3))*180/pi
 translate <2,-1.15>
 }

  
/*plane{
 y,-1
 texture{pigment{color rgb 1}}
 }
 
object{obj
 rotate y*360*clock
 }*/