// Alex Kluchikov, 2003
// mailto: klkspa[at]ukr.net, aklk[at]mail.ru
// Feel free to modify/use in any form

sky_sphere{pigment{gradient y color_map{[0,color rgb <0.7,0.75,1>][1,color rgb <0.2,0.5,1>]}scale 2 translate -y}}
sphere{0,1000 texture{pigment{bozo color_map{[0,color rgbt <1,1,1,0.>][.5,color rgbt <.5,.5,.5,0.25>][1,color rgbt<0,0,0,0.>]}}scale 0.25 
                      finish{ambient 1 diffuse 0}scale 3000}no_shadow no_image double_illuminate hollow}
camera{
 location -1.3*z
 look_at 0
 rotate x*5
 rotate y*-27
 }          
 
light_source{        
 -5*z, color rgb <1.0,0.9,0.8>*0.6
 parallel
 rotate x*20 rotate y*20
 }
light_source{
 -5*z, color rgb <0.8,0.9,1>*0.6
 parallel
 rotate x*30 rotate y*60
 }

#declare st=texture{pigment{color rgb<0.83,0.82,0.87>*1.2}
  finish{diffuse 0.75 ambient 0 specular 0.9 roughness 0.03 phong 0.5 brilliance 8 phong_size 80  metallic 0.8 reflection{0.4,0.9 metallic}}
  }
 
#declare blb=function(x,y,z,a,b,c,d) 
 {
  d/(pow(x-a,4)+pow(y-b,4)+pow(z-c,4)+0.001)
 }

#declare bc=9;
#declare s=0.001;
#declare r=0.25;
#declare aa1=array[bc][8]
 {
  { 0, 0, 0,s,1,1,1,.3}
  { r, r, r,s, 1,.6,.7,.9}
  { r, r,-r,s, 1, 1,.5,.5}
  { r,-r, r,s,.6, 1,.5,.7}
  { r,-r,-r,s,.7, 1,.5,.6}
  {-r, r, r,s,.7,.8,.5,.6}
  {-r, r,-r,s, 1,.6,.5,.6}
  {-r,-r, r,s, 1,.5,.5,.8}
  {-r,-r,-r,s,.5, 1,.6,.8}
 }



#declare fn_X = function(x,y,z) {1
 #declare i=0;
 #while(i<bc)
 -blb(x,y,z,aa1[i][0],aa1[i][1],aa1[i][2],aa1[i][3])
 #declare i=i+1;
 #end
 }

isosurface {
  function { fn_X(x, y, z) } 
  contained_by { box {-0.4,0.4} }
  threshold 0
  accuracy 0.001 
  max_gradient 7
 texture{
  st
  pigment{average pigment_map{
   [1 function{
    #declare i=0;
    #while(i<bc)
     +blb(x,y,z,aa1[i][0],aa1[i][1],aa1[i][2],aa1[i][3])*aa1[i][4]
    #declare i=i+1;
    #end
   }colour_map{[0,rgb 0][1,red 4]}]
   [1 function{
    #declare i=0;
    #while(i<bc)
     +blb(x,y,z,aa1[i][0],aa1[i][1],aa1[i][2],aa1[i][3])*aa1[i][5]
    #declare i=i+1;
    #end
   }colour_map{[0,rgb 0][1,green 4]}]
   [1 function{
    #declare i=0;
    #while(i<bc)
     +blb(x,y,z,aa1[i][0],aa1[i][1],aa1[i][2],aa1[i][3])*aa1[i][6]
    #declare i=i+1;
    #end
   }colour_map{[0,rgb 0][1,blue 4]}]
   [1 function{
    #declare i=0;
    #while(i<bc)
     +blb(x,y,z,aa1[i][0],aa1[i][1],aa1[i][2],aa1[i][3])*aa1[i][7]
    #declare i=i+1;
    #end
   }colour_map{[0,rgbt 0][1,transmit 4]}]
  }
 }
}
interior{ior 1.32}
rotate y*-90
}

plane{y,-0.4 texture{st pigment{
 average pigment_map{
  [1,bozo color_map{[0,color rgb 0][1,color red 3]}]
  [1,bozo rotate 30 color_map{[0,color rgb 0][1,color green 3]}]
  [1,bozo rotate 60 color_map{[0,color rgb 0][1,color blue 3]}]
  }
 }}}

fog {
  distance 150
  color rgb<0.7, 0.75, 1.0>
    fog_type 2
    fog_offset 5
    fog_alt 1
  
}

sphere{0,500 
 scale x+z+y*0.03
 texture{
  pigment{granite pigment_map{[0,color rgb 1 transmit 0.7]
                              [1,color rgb 1 transmit 1]}}
  finish{ambient 0.3 diffuse 1}
  scale 140+z*150
 }           
 double_illuminate hollow
}    

sphere{0,550 
 scale x+z+y*0.03
 texture{
  pigment{granite pigment_map{[0,color rgb 1 transmit 0.7]
                              [1,color rgb 1 transmit 1]}}
  finish{ambient 0.6 diffuse 1}
  scale 140+z*150
 }           
 double_illuminate hollow
}    

sphere{0,600 
 scale x+z+y*0.03
 texture{
  pigment{granite pigment_map{[0,color rgb 1 transmit 0.7]
                              [1,color rgb 1 transmit 1]}}
  finish{ambient 1 diffuse 2}
  scale 140+z*150
 }           
 double_illuminate hollow
}    

sphere{0,650 
 scale x+z+y*0.03
 texture{
  pigment{granite pigment_map{[0,color rgb 1 transmit 0.7]
                              [1,color rgb 1 transmit 1]}}
  finish{ambient 1 diffuse 4}
  scale 140+z*150
 }           
 double_illuminate hollow
}