#version unofficial MegaPov 1.2;

default { pigment { color rgb 0.75 } finish { ambient 0 diffuse 0.5 }}

#include "colors.inc"
#include "textures.inc"
#include "stones.inc"
#include "metals.inc"
#include "functions.inc" 
#include "transforms.inc" 
#include "glass.inc" 
#include "rand.inc" 
#include "rwm_materials.inc"

//------------------------------------------------------------------------------
// Globals and radiosity settings 
//------------------------------------------------------------------------------

#declare R = seed(19630816);
#declare R1 = seed(1963);

#declare Use_Blur         = 7*2; // blur samples (0=off)
#declare Render_CGSphere  = 1; 
#declare Render_Ramp      = 1; 
#declare Render_Particles = 1; 
#declare Soft_Shadows     = 1;
#declare Trace_Level      = 20;  
#declare Quick_Render     = 0;  

/*
#declare Use_Radiosity    = 1;  
#declare Rad_Bounce       = 2;      // higher is (usually) better 
#declare Rad_Count        = 80;     // higher is better
#declare Rad_NearestCount = 8;      // 5 - 20, higher is better
#declare Rad_ErrorBound   = 0.75;   // lower is better  
#declare Rad_Pretrace     = 0.01;   // lower is better
#declare Rad_Brightness   = 2;  
#declare Rad_File = "";
#include "rwm_rad2.inc"  
*/
global_settings { radiosity{} }
global_settings { exposure 1.5 }
global_settings { photons { count 20000 media 100 } }


camera{ 
  // orthographic
  up y
  right x*image_width/image_height
  angle 41
  location -z*201.5
  //location <250, 250, -250>*2
  //location x*500
  look_at  0
  #if (Use_Blur)
    aperture 2             // [0...N] larger is narrower depth of field (blurrier)
    blur_samples Use_Blur  // number of rays per pixel for sampling
    focal_point 0
    confidence 1           // [0...1] when to move on while sampling (smaller is less accurate)
    variance 1/10000
  #end
}                           

#include "CGSphere.inc"

light_source {
   <280, 365, -435>
   rgb Sunlight*3
   #if (Soft_Shadows) 
      area_light <100, 0, 0>, <0, 0, 100>, 5, 5
      adaptive 2
      jitter
      orient 
      circular
   #end
}
light_source {
   <-280, 365, -435>
   rgb Sunlight*1.5
   shadowless
}

//-----------------------------------------------------------------------------
// Sky
//-----------------------------------------------------------------------------
 
sphere {0, 1000
   hollow
   pigment { image_map {hdr "TG_Probe01.hdr" map_type 7 interpolate 2 }}
   finish { ambient 1 diffuse 0 }
   no_shadow
}

//-----------------------------------------------------------------------------
// Ramp tiles
//-----------------------------------------------------------------------------
 
#if (Render_Ramp)
   object { Ground 
      #if (Quick_Render)
         pigment {rgb 0} 
         finish { diffuse 0.5 ambient 0 reflection {0, 0.5} conserve_energy }
      #else
      texture {
         pigment { uv_mapping
            gradient x
            pigment_map{
               [1/80 rgb 0]
               [1/80 
                  gradient y 
                  pigment_map{
                     [1/80 rgb 0]
                     [1/80 
                        average 
                        pigment_map {
                           [2 image_map { png "CrackedPlasterTile.png" interpolate 2 transmit all 0.0} scale 1.37]
                           [1 image_map { png "CrackedPlasterTile.png" interpolate 2 transmit all 0.0} rotate z*10]
                           [1 rgb 0.5]
                        }
                        scale <15, 20, 15>*0.5 
                        rotate x*45
                     ]
                  }
               ]
            }
            scale -<1/10,1/20,1>
         }
         normal { uv_mapping
            gradient x
            normal_map{
               [1/80 bumps -0.1 scale 0.1]
               [1/80 
                  gradient y 
                  normal_map{
                     [1/80 bumps -0.1 scale 0.1]
                     [1/80 
                        average 
                        normal_map {
                           [2 bump_map { png "CrackedPlasterTile.png" interpolate 2} scale 1.37]
                           [1 bump_map { png "CrackedPlasterTile.png" interpolate 2 } rotate z*10]
                        }
                        scale <15, 20, 15>*0.5 
                        rotate x*45
                     ]
                  }
               ]
            }
            scale -<1/10,1/20,1>
         }
         finish { diffuse 0.4 ambient 0 specular 0.25 roughness 0.01 reflection {0, 0.5} conserve_energy }  
      }
      #end
   }
#end

#if (Render_Particles)
   #include "steamBall.inc" 
   object {SteamBall}
   //object {SteamBall rotate x*180 rotate y*180 scale 1.1}
#end

#if (Render_CGSphere)
   // Balls
   
   //-----------------------------------------------------------------------------
   // Materials
   //-----------------------------------------------------------------------------
   
   #declare P1 = pigment { 
      bozo 
      turbulence 0.5 
      scale 0.1 
      color_map {[0 rgb<189,112,40>/255*1.2 transmit 0.8][1 rgb<143,61,5>/255*1.2 transmit 0.9]} 
   }
   
   #declare M_Glass1 = 
   material {
      texture {
         pigment {
            bozo
            scale 0.25
            turbulence 0.5
            pigment_map { 
               [0.000 P1]
               [0.675 P1]
               [1.000 color (Turquoise+SeaGreen)/2*1.5 ]
            }
         }
         normal { N_Stucco scale 10}
         finish {
            specular 0.15
            roughness 0.005
            brilliance 4
            reflection { 0.0, 0.15 fresnel on }
            conserve_energy
         }
      }
      texture {
         pigment {
            bozo
            scale 0.175
            turbulence 0.45
            pigment_map { 
               [0.0 P1]
               [0.7 P1]
               [1.0 SeaGreen*0.75 ]
            }
         }
         normal { N_Stucco scale 20}
         finish {
            specular 0.2
            roughness 0.005
            reflection { 0.0, 0.15 fresnel on }
            conserve_energy
         }   }
      interior {ior 1.1}
   }
   
   
   #declare T_Main = 
   texture {           
      pigment {      
         average
         pigment_map {
            [2 granite
               turbulence 0.2
               scale 0.5
               color_map {
                  [0.00 Yellow*0.5 ]
                  [0.25 P_Gold3 ]
                  [0.50 rgb 1.2 ]
                  [0.75 rgb<189,112,40>/255 ]
                  [1.00 rgb<143,61,5>/255 ]
               }
               scale 10
            ]
            [2 agate
               turbulence 0.7
               scale 0.4
               color_map {
                  [0 rgb 1.25]
                  [0.1 ForestGreen*0.5]
                  [0.5 rgb 1.25]
                  [0.71 rgb<189,112,40>/255]
                  [0.5 rgb 1.25]
                  [0.71 Yellow]
                  [0.72 rgb 1.2]
                  [1 rgb 1.2]
               }
               scale 2 
            ]
         }
         scale 0.5
      }
      normal {N_Stucco bump_size 10} 
      finish {diffuse 0.25 roughness 0.01 specular 0.05 conserve_energy} 
   }
   texture {
      pigment {
         bozo
         turbulence 0.75
         scale 0.015
         color_map {
            [0 rgbt 1]
            [0.675 rgbt 1]
            [1 Red*0.5 ]
         }
      }
      normal {N_Stucco bump_size 10} 
   }
   texture {
      pigment {
         bozo
         turbulence 0.75
         scale 0.0125
         color_map {
            [0 rgbt 1]
            [0.675 rgbt 1]
            [1 Red ]
         }
      }
      normal {N_Stucco bump_size 10} 
   }
   
   //-----------------------------------------------------------------------------
   // Materials
   //-----------------------------------------------------------------------------
   
   #include "MultiHoleBall1.inc"
   
   #declare CGSphere1 = union { 
      light_group {
         //light_source {<0, 0, -100> color rgb 0.5 shadowless} 
         object {MultiHoleBall1 rotate 0 scale 4 #if (!Quick_Render) texture {T_Hammered_Gold} #else pigment {rgb 0} finish {reflection{0,0.5 fresnel} conserve_energy} #end}
         global_lights true
      }
      
      light_group {
         //light_source {<0, 0, -100> color rgb 0.5 shadowless} 
         object {MultiHoleBall1 rotate 50 scale 6 double_illuminate
            #if (!Quick_Render) material {M_Glass1}  #else pigment {rgb 0} finish {reflection{0,0.5 fresnel} conserve_energy} #end
         }
         global_lights true
      }
      
      light_group {
         //light_source {<0, 0, -100> color rgb 0.5 shadowless} 
         object {MultiHoleBall1 rotate 120 scale 8 #if (!Quick_Render) texture {T_Hammered_Gold} #else pigment {rgb 0} finish {reflection{0,0.5 fresnel} conserve_energy} #end}
         global_lights true
      }
      
      light_group {
         //light_source {<0, 0, -100> color rgb 0.5 shadowless} 
         object {MultiHoleBall1 rotate -50 scale 10 double_illuminate 
            #if (!Quick_Render) material {M_Glass1}  #else pigment {rgb 0} finish {reflection{0,0.5 fresnel} conserve_energy} #end
         }
         global_lights true
      }
      scale 3
   }
   
   #declare CGSphere1 = object {CGSphere1 Center_Trans(CGSphere1, x+y+z)}
   object {CGSphere1 translate y*1 photons { target refraction on }}
#end