// Persistence Of Vision Ray Tracer Scene Description File
// File: tree.pov
// Vers: 3.6.1
// Desc: A fractal inspired by the pythagoras tree
// Auth: Archpawn Daniel Carrier

camera{
   location <2,3,8>
   look_at y
   angle 45
}
light_source{
   <2,3,8>
   rgb 1
}
#declare Mult=1/pow(3,1/3);
#declare Branch0=prism{
   conic_sweep
   linear_spline
   Mult,1,4
   <0,1/sqrt(3)>,
   <.5,-1/(2*sqrt(3))>,
   <-.5,-1/(2*sqrt(3))>,
   <0,1/sqrt(3)>
   translate -y
   scale <1,1/(Mult-1),1>
}
#declare Green=y;
#declare Brown=<150,75,0>/255;
#declare Size=1;
#declare Branch=object{Branch0 pigment{color rgb Green}};
#declare Iteration=0;
#declare Max=9;
#while(Iteration<Max)
   #declare Branch=union{
      object{Branch0 pigment{color rgb (Green-Brown)*Size*Size+Brown}}
      object{Branch translate z/(2*sqrt(3)) rotate -x*atan(3)*180/pi translate z*-1/(2*sqrt(3)) scale Mult translate y}
      object{Branch translate z/(2*sqrt(3)) rotate -x*atan(3)*180/pi translate z*-1/(2*sqrt(3)) scale Mult translate y rotate y*120}
      object{Branch translate z/(2*sqrt(3)) rotate -x*atan(3)*180/pi translate z*-1/(2*sqrt(3)) scale Mult translate y rotate y*-120}
   }
   #declare Size=Size*Mult;
   #declare Iteration=Iteration+1;
#end
object{Branch}