#include "logo.inc"

#default {finish {ambient 0}}

#include "colors.inc"
#include "rad_def.inc"


global_settings 
{
  assumed_gamma 1.0 
  radiosity {}
}


camera 
{
  location  <0.0, 2.0, -5.0>
  look_at   <0.0, 2.0,  0.0>
  angle 90
}


light_source 
{
  < -20,  15, -5> color 5*White
  //parallel point_at <0,0,-5>
}


// Fill
light_source 
{
  < -5,  5, -5> color 0.05*White
  shadowless
} 

sphere
{
  0, 1000 pigment {color SkyBlue} hollow
}



#declare ROOM_WIDTH     =  14;
#declare ROOM_HEIGHT    =   7;
#declare ROOM_DEPTH     =  20;
#declare WT             = 0.2; // Wall thickness


#declare WINDOW_THICKNESS = 0.1;
#declare WINDOW_RADIUS    = 1.5;
#declare WINDOW_HEIGHT    = 2.0;

#declare WINDOW_POS_Y   =  1.5;
#declare WINDOW_POS_Z_1 =  11.0;
#declare WINDOW_POS_Z_2 = - 6.0;


// Floor with tiling
#declare P_FLOOR = pigment
{
  tiling 16 // 1~24 Pattern_Number
  color_map
  {
    [ 0/3 color rgb 1]
    [ 1/3 color rgb 0]
    [ 1/3 color rgb 1]
    [ 2/3 color rgb 0]
    [ 2/3 color rgb 1]
    [ 3/3 color rgb 0]
  }
}


box 
{
  <-5,-0.5,-10>, <10,0,10> 
  
  pigment {color White}
 
  #declare G = function {pigment {P_FLOOR}}
    
  normal
  {
    function
    {
      G(x,y,z).red
    }
    scale 0.5
  }
}

                                                   

// Windows

#declare WINDOW_SHAPE = union
{
  box
  {
    <0,0,0>,<WINDOW_THICKNESS,WINDOW_HEIGHT,2*WINDOW_RADIUS> 
  }
  cylinder 
  {
    0,WINDOW_THICKNESS*x,WINDOW_RADIUS translate <0,WINDOW_HEIGHT,WINDOW_RADIUS>
  }
}



#declare WINDOW = object
{ 
  WINDOW_SHAPE
  pigment
  {
    tiling 5 // 1~24 Pattern_Number

    color_map
    {
      [ 0.0/3 color rgbf <1,0,0,1>]
      [ 0.5/3 color rgbf <1,0,0,1>]
      [ 1.0/3 color rgbf <0,0,0,1>]
      [ 1.0/3 color rgbf <0,1,0,1>]
      [ 1.5/3 color rgbf <0,1,0,1>]
      [ 2.0/3 color rgbf <0,0,0,1>]
      [ 2.0/3 color rgbf <0,0,1,1>]
      [ 2.5/3 color rgbf <0,0,1,1>]
      [ 3.0/3 color rgbf <0,0,0,1>]
    }
    
    scale 0.5
    
    rotate -90*z
  } 

  normal
  {
    bozo 0.5 scale 0.01
  }
  
  finish
  {
    reflection 0.1
  }  
  
  interior {ior 1.5}
}


// Room

#declare ROOM = difference
{
  box {<-WT, -WT, -WT>,  <ROOM_WIDTH+WT, ROOM_HEIGHT+WT,ROOM_DEPTH+WT>}
  box {<0.0, -0.1, 0.0>, <ROOM_WIDTH,    ROOM_HEIGHT,   ROOM_DEPTH>}
  union
  {
    object {WINDOW_SHAPE scale 100*x translate -5*x translate WINDOW_POS_Z_1*z}
    object {WINDOW_SHAPE scale 100*x translate -5*x translate WINDOW_POS_Z_2*z}
    translate WINDOW_POS_Y*y
  }
  pigment {color White}
}


// Centered room with windows
union
{
  object {ROOM}


  union
  {
    object {WINDOW translate WINDOW_POS_Z_1*z}
    object {WINDOW translate WINDOW_POS_Z_2*z}
    translate WINDOW_POS_Y*y
    translate -WT/2*x
    translate -WINDOW_THICKNESS/2*x
  }
  
  translate -<ROOM_WIDTH/2,0,ROOM_DEPTH/2>
}


// Fertility Symbols
#declare OVUS = ovus
{
 1,0.8 pigment {color White}
 translate y
 scale 0.8 
}
  
object {OVUS translate <-ROOM_WIDTH/2+2.5,0,ROOM_DEPTH/2-3>} 
object {OVUS translate <+ROOM_WIDTH/2-2.5,0,ROOM_DEPTH/2-3>} 


// Altar

object
{
  Povray_Logo
  texture
  {
    pigment {colour White}
    finish {emission 0.5}
  }
  translate y
  scale 3
  translate (ROOM_DEPTH/2-3)*z
}