// Expected dimension 680 x 280
#include "logo.inc"
#include "glass.inc"
#include "finish.inc"
#include "golds.inc"
global_settings { max_trace_level 255 }
camera { orthographic 
	location <0.0,0.0,-100>
		direction z
		up 10*y
		right 10*x*image_width/image_height
}
#include "colors.inc"
plane { z,1 texture { pigment { color White } finish { ambient 0.7 diffuse 0.3 }}}

plane { y,-5 texture { pigment { checker color White color Black scale 7} finish { ambient 0.8 diffuse 0.2 }}}

light_source { <10,15,-20>*100,1.0 
area_light 700*x,700*y, 9,9 jitter circular

}
#declare Myred = texture { pigment { colour Red} normal { granite 1.0 scale 1/2}};
#declare Myblue = texture { pigment { colour Blue} normal { granite 1.0 scale 1/2 }};
#declare Mygreen = texture { pigment { colour Green} normal { granite 1.0 scale 1/2}};

#include "shapes.inc"
#declare TextRatio = 0.86;
#declare Cut_Number=25;
#declare Cut_Angle=18;
#macro Bluetext(tt,xx,yy)
object { Bevelled_Text("Maiandb.ttf",tt,Cut_Number,Cut_Angle,0.1,.1,0,0)
	scale 4 texture  { Myblue } 
	scale <TextRatio,1,1>
	translate <xx,yy,00>
}
#end
#macro Redtext(tt,xx,yy)
object { Bevelled_Text("Maiandb.ttf",tt,Cut_Number,Cut_Angle,0.1,.1,0,0)
	scale 6 texture  { Myred } 
	scale <TextRatio,1,1>
	translate <xx,yy,00>
}
#end

#macro Greentext(tt,xx,yy)
object { Bevelled_Text("Maiandb.ttf",tt,Cut_Number,Cut_Angle,0.1,.1,0,0)
	scale 3 
	texture  { Mygreen } 
	rotate 40*z
	translate <xx,yy,00>
}
#end
sphere_sweep { linear_spline 2, 
	<-10,-4,1>,0.2,
	<11,-4,1>,0.2
		texture { T_Gold_2A finish {reflection 0}}
	translate 0.5*y
}
sky_sphere {   pigment { color  White }  }
object { Povray_Logo texture { pigment { colour Blue }  finish { F_Glass3 }  }
	interior { I_Glass3 }
	scale 4 translate <-8,1,0.9> }

Bluetext("ersistence",-5,2)
Redtext("VISI",-6,-3)
Redtext("N",7,-3)
Greentext("of",-7.5,-3.3)
#declare Myovus=texture {
	uv_mapping pigment { tiling 8
		
		pigment_map
		{
			[0/24 DustyRose]
			[7/24 DustyRose]
			[7/24 White]
			[8/24 White]

			[8/24 SpicyPink]
			[9/24 SpicyPink]
			[9/24 Gold]
			[12/24 Gold]
			[12/24 SpicyPink]
			[15/24 SpicyPink]
			[15/24 White]
			[16/24 White]

			[16/24 DarkTan]
			[17/24 DarkTan]
			[17/24 Black]
			[20/24 Black]
			[20/24 DarkTan]
			[23/24 DarkTan]
			[23/24 White]
			[24/24 White]

		}
	}
	rotate 90*x
		translate 1.9*y
	scale <1/8,1/4,1/4>*2/4
};
ovus { 2,4/3 texture { Myovus } scale 8/10 translate <5.4,-1.4,0>}