#declare T_Beach=
texture
{
  pigment { color rgb <1, 1, 0.5> }
  finish { ambient 0.05 diffuse 1 brilliance 0.25 }
}

#declare T_Meadow=
texture
{
  pigment { color rgb <0.1, 0.7, 0.2> }
  finish { ambient 0.05 diffuse 1 brilliance 0.5 }
}

#declare T_Forest=
texture
{
  pigment { color rgb <0, 0.5, 0.2> }
  finish { ambient 0.05 diffuse 1 brilliance 0.42 }
}

#declare T_Shrub=
texture
{
  pigment { color rgb <0.65, 0.78, 0.2> }
  finish { ambient 0.05 diffuse 1 brilliance 0.31 }
}

#declare T_Rock=
texture 
{
  pigment { color rgb 0.7 }
  finish { ambient 0.05 diffuse 1 brilliance 0.5 }
}

#declare T_Snow=
texture
{
  pigment { color rgb 1 }
  finish { ambient 0.05 diffuse 1 brilliance 0.18 }
}

#declare TM_Shore=
texture
{
  slope { <0, -1, 0> }
  texture_map
  {
    [0     T_Beach ]
    [0.035 T_Beach ]
    [0.036 T_Forest ]
    [0.4 T_Forest ]
    [0.4 T_Rock ]
    [0.5 T_Rock ]
  }
}

#declare TM_Lowlands=
texture
{
  slope { <0, -1, 0> }
  texture_map
  {
    [0     T_Meadow ]
    [0.06  T_Meadow ]
    [0.065 T_Forest ]
    [0.4 T_Forest ]
    [0.4 T_Rock ]
    [0.5 T_Rock ]
  }
}

#declare TM_Highlands=
texture
{
  slope { <0, -1, 0> }
  texture_map
  {
    [0   T_Forest ]
    [0.4 T_Forest ]
    [0.4 T_Rock ]
    [0.5 T_Rock ]
  }
}

#declare TM_SubAlpine=
texture
{
  slope { <0, -1, 0> }
  texture_map
  {
    [0   T_Shrub ]
    [0.4 T_Shrub ]
    [0.4 T_Rock ]
    [0.5 T_Rock ]
  }
}

#declare TM_Alpine=
texture
{
  slope { <0, -1, 0> }
  texture_map
  {
    [0   T_Snow ]
    [0.4 T_Snow ]
    [0.4 T_Rock ]
    [0.5 T_Rock ]
  }
}

#declare TMM_Tasmania=
texture
{
  gradient y
  texture_map
  {
    [0	TM_Shore]
    [3  TM_Shore]
    [3  TM_Lowlands]
    [200 TM_Lowlands]
    [200 TM_Highlands]
    [600 TM_Highlands]
    [600 TM_SubAlpine]
    [1200 TM_SubAlpine]
    [1200 TM_Alpine]
  }
  turbulence 0.06
  octaves 8
}



#declare sea= // code by Christoph Hormann, slightly modified
material {
  texture {
    pigment {
      color rgbt <1, 1, 1, 1>
    }
    finish {
      diffuse 0

      reflection {
	<0.03, 0.03, 0.04>, <0.75, 0.75, 1>
	exponent 1.2
	falloff 5
	fresnel on
      }

      phong 1
      phong_size 2500000
    }
    normal 
    {
      bozo 1.5  
      bump_size 0.5
      scale 0.00000013
    }  
      
    
  }
  interior {
    ior 1.34
  }
}



sky_sphere
{
  pigment
  {
    gradient y
    color_map
    {
      [0     rgb <0.7, 1, 1>]
      [0.15  rgb <0, 0.7, 1>]
      [0.3   rgb <0, 0.4, 1>]
      [1     rgb <0, 0.4, 1>]
    }
  }
}

light_source
{
  <0, 400000, 300000>
  color rgb 1
}

#declare hf=2;

#switch(hf)
  #case (0)
    #declare file="arg06_a.tga";
    #declare xdim=1000;
    #declare zdim=1000;
    #declare sc=<5000, 3000, 5000>;
    #declare xsc=5;
  #break
  #case (1)
    #declare file="afgand1.tga";
    #declare xdim=1000;
    #declare zdim=1000;
    #declare sc=<111305.555, 9270, 111305.555>;
    #declare xsc=111.305555;
  #break
  #case (2)
    #declare file="s44e146_patched.png"
    #declare xdim=1200;
    #declare zdim=1200;
    #declare sc=<111305.555, 9270, 111305.555>;
    #declare xsc=sc.x/xdim;
    #declare tr=<0, -422, 0>;
  #break
#end

#declare terrain=
height_field
{
  png file
  smooth
  double_illuminate
  scale sc
  translate tr
}

plane
{
  y, 0.001
  texture
  {
    pigment { color rgb <0, 0, 0.3> }
  }
}

plane
{
  y, 0.01
  material { sea }
}
   


object
{
  terrain
  texture { TMM_Tasmania }
}

#declare xpos=667;
#declare zpos=640;
#declare h=500;
#declare dir=45;
#declare azi=-15;
#declare tracebas=<xpos*xsc, -1000, (zdim-zpos)*xsc>;

#declare camPos=trace(terrain, tracebas, y)+y*h;
#declare camLook=camPos+<sin(radians(dir))*cos(radians(azi)), sin(radians(azi)), cos(radians(dir))*cos(radians(azi))>;

camera
{
  location camPos
  look_at camLook
}