#include "functions.inc"
#include "rheinruhr.inc"

#declare os=0; // 0: Linux, 1: Windows
#switch (os)
  #case (0)
    #declare path="";
  #break
  #case (1)
    #declare path="../SRTM/png_patched/";
  #break
#end

global_settings
{
  assumed_gamma 2.2
}

#declare xdim=2400;
#declare ydim=2400;

#declare deadsea=0.422;
#declare everest=8.848;
#declare rng=deadsea+everest;
#declare rd=6378.14;

#declare latstart=52;
#declare longstart=6;

#declare res=1200;

#declare map=
pigment
{
  image_map
  {
    png concat(path, "rheinruhr.png")
  }
}

#declare Cam_Azi=0;
#declare Cam_Dir=270;
#declare Cam_Lat=50.6473;
#declare Cam_Long=7.191;
#declare Cam_Height=0.0017;

#declare Earth_Pos=0;
#declare Earth_Tilt=23.439281;
#declare Earth_Rot=0;

#declare Earth_Slice=
object
{
  Earth_Slice_RheinRuhr
  texture
  {
    pigment { color rgb <0, 0.8, 0> }
    finish { ambient 0.1 diffuse 1 brilliance 0.4 }
  }
  rotate <0, Earth_Rot, 0>
  rotate <Earth_Tilt, 0, 0>
}



#declare Cam_surfpos=trace(Earth_Slice, Earth_Pos, <sin(radians(-Cam_Long))*cos(radians(Cam_Lat)), sin(radians(Cam_Lat)), cos(radians(-Cam_Long))*cos(radians(Cam_Lat))>);
#declare Cam_Pos=Cam_surfpos+vnormalize(Cam_surfpos)*Cam_Height;
#declare Cam_Pos=vrotate(Cam_Pos, <0, Earth_Rot, 0>);
#declare Cam_Pos=vrotate(Cam_Pos, <Earth_Tilt, 0, 0>);
#declare Cam_Look=<sin(radians(Cam_Dir))*cos(radians(Cam_Azi)), sin(radians(Cam_Azi)), cos(radians(Cam_Dir))*cos(radians(Cam_Azi))>;
#declare Cam_Look=vrotate(Cam_Look, <90-Cam_Lat, -Cam_Long, 0>);
#declare Cam_Look=vrotate(Cam_Look, <0, Earth_Rot, 0>);
#declare Cam_Look=vrotate(Cam_Look, <Earth_Tilt, 0, 0>);
#declare Cam_Look=Cam_Pos+Cam_Look;
#declare Cam_Sky=<0, 1, 0>;
#declare Cam_Sky=vrotate(Cam_Sky, <90-Cam_Lat, -Cam_Long, 0>);
#declare Cam_Sky=vrotate(Cam_Sky, <0, Earth_Rot, 0>);
#declare Cam_Sky=vrotate(Cam_Sky, <Earth_Tilt, 0, 0>);


object
{
  Earth_Slice
}


/* sphere
{
  0, rd
  texture
  {
    pigment { color rgb <0, 0, 0.4> }
    finish { ambient 0.1 diffuse 1 brilliance 0.6 }
  }
} */
    

camera
{
  location Cam_Pos
  look_at Cam_Look
  sky Cam_Sky
  angle 40
}

/* camera
{
  location <-100000, 0, 100000>
  look_at 0
  angle 4
} */


light_source
{
  <-149600000, 0, 0>
  color rgb 1
}