#include "colors.inc"
#include "glass.inc"
#include "shapes.inc"

#declare Radiosity = off;
#declare FocalBlur = off;
#declare AreaLightW = 8;
#declare AreaLights = 8;

#declare GAP = 0.001;

global_settings {
	assumed_gamma 1
	max_trace_level 256
	#if (Radiosity)
		radiosity {
			pretrace_start 0.08
			pretrace_end   0.04
			count 35

			nearest_count 5
			error_bound 1.8
			recursion_limit 3

			low_error_factor 0.5
			gray_threshold 0.0
			minimum_reuse 0.015
			brightness 0.4

			adc_bailout 0.01/2
		}
	#end
}

camera {
	location  <0,3.3,-4.6> * 2.0
	direction z * 2
	right     x*4/4
	look_at   <0,-0.5,-0.5>
	#if (FocalBlur)
		focal_point < 0,1,-1>    // pink sphere in focus
		aperture 1.5     // much blurring
		blur_samples 20      // more samples, higher quality image
	#end
}

light_source {
    <0,30,-3>
    1
    #if (AreaLights > 0)
		area_light <AreaLightW, 0, 0>, <0, 0, AreaLightW>, AreaLights, AreaLights
	#end
}

plane {
	y,-1.6
	pigment{ color <2,2,2> }
}

/* X, Y and Z axis */
#if(false)
	cylinder {
		<0,  0,0>
		<0,100,0>
		0.2
		pigment { Red }
	}
	cylinder {
		< 0,0,0>
		<100,0,0>
		0.2
		pigment { Green }
	}
	cylinder {
		<0,0,  0>
		<0,0,100>
		0.2
		pigment { Blue }
	}
#end


#macro Wedge(Start,End,Pigment,Height)
	merge {
		difference {
			torus {
				2, 0.6
			}
			#if( (End - Start) < 180 )
				plane {
					-x,0
					translate <-1 * GAP,0,0>
					rotate <0,Start,0>
				}
				plane {
					x,0
					translate <GAP,0,0>
					rotate <0,End,0>
				}
			#end
			#if( (End - Start) = 180 )
				plane {
					-x,0
					translate <-1 * GAP,0,0>
					rotate <0,Start,0>
				}
			#end
			#if( (End - Start) > 180 )
				intersection {
					plane {
						-x,0
						translate <-1 * GAP,0,0>
						rotate <0,Start,0>
					}
					plane {
						x,0
						translate <GAP,0,0>
						rotate <0,End,0>
					}
				}
			#end

			torus {
				0.6, 0.1
				rotate x*90
				translate x * 2
				rotate y * (90 + Start)
			}
			torus {
				0.6, 0.1
				rotate x*90
				translate x * 2
				rotate y * (90 + End)
			}


		}

		torus {
			0.5, 0.1
			rotate x*90
			translate x * 2
			rotate y * (90 + Start + 2.66)
		}
		torus {
			0.5, 0.1
			rotate x*90
			translate x * 2
			rotate y * (90 + End - 2.66)
		}

		texture {
			pigment { Pigment filter 0.35  }
			finish {
				ambient 0.75
				diffuse 0.1
				reflection .15
				specular 1
				roughness 0.001
			}

		}
	}
#end

Wedge( 0, 14.7/100*360, Magenta, 0 )
Wedge( 14.7/100*360, (14.7+71.78)/100*360, Red, 0.3 )
Wedge( (14.7+71.78)/100*360, (14.7+71.78+12.09)/100*360, Blue*2, 0.2 )
Wedge( (14.7+71.78+12.09)/100*360, 360, Orange, 0.1 )