/////////////////////////////////////////////////////////////////////////////
// Include Files

#include "colors.inc"
#include "skies.inc"

/////////////////////////////////////////////////////////////////////////////
// Global Settings

background { Black }
#default
{
	pigment { Gray75 }
	finish
	{
    ambient .25
	  diffuse .75
	  reflection 0
	  phong 0
	  phong_size 30
	}
}

/////////////////////////////////////////////////////////////////////////////
// Sky

sky_sphere
{
  S_Cloud1
  rotate <90, 0, 0>
}

/////////////////////////////////////////////////////////////////////////////
// Lights


light_source
{
  <1, 1, 1>*100000
  colour White
}

/////////////////////////////////////////////////////////////////////////////
// Camera

camera
{
  location <.25, 1, .5>*5000
  direction <2.5,0,0>
  up z
  right <0, -(image_width/image_height), 0>
  sky z
  look_at <0, 0, 0>
}

/////////////////////////////////////////////////////////////////////////////
// Objects

//Stars
#macro Star(vPosition, fMag)
	sphere
	{
		vPosition*1000, (6-fMag)*2
		pigment{White}
	}
#end

#include "starmap.inc"

//Sphere
sphere
{
	0, 
	1000 
	pigment{Gray25}
}

//Grid lines
union
{
	#local rz=0;
	#while(rz<180)
		#if(rz=0)
			torus{1000, 2.5 rotate<0, 0, rz>}
		#else
			#if(rz=90)
				torus{1000, 2.5 rotate<0, 0, rz>}
			#else
				difference
				{
					torus{1000, 2.5 rotate<0, 0, rz>}
					cylinder{<0, 0, 0>, <0, 0, 1100>, 1000*sin(radians(10))}
				}
			#end
		#end
		#local rz=rz+15;
	#end
	#local fDec=-80;
	#while(fDec<=80)
		torus{cos(radians(fDec))*1000, 2.5 rotate<90, 0, 0> translate<0, 0, sin(radians(fDec))*1000>}
		#local fDec=fDec+10;
	#end
	pigment{Gray40}
}