#include "colors.inc"
#include "metals.inc"

/**************************************************
 * Secret Laboratory Interior                     *
 *                                                *
 * Unit = 1 foot 				  *
 *						  *
 * It's on old army shed that has been converted  *
 **************************************************/
 
light_source{
  <0,1,0> 
  color White
}

light_source{
	<100,100,100>
	color White
}

camera{
  location <0,1,0>
  look_at <50,5.5,0>
}

#declare RAD=9;
#declare LEN=50;

// Basic military hutch interior
difference{ 
	isosurface{
		// This creates the corragated metal hull
		function{
			sqrt(pow(y,2)+pow(z,2))+(sin(atan2(z,y)*pi*RAD*6)/24)
		}
		threshold RAD
		contained_by{
			box{
				<0,-19, 0>, <LEN,19,19>
			}
		}
		open
		rotate <-90,0,0>
	}
	// Now create the opennings for the hutch
	// These are 1 x 2 holes in the wall.
	#declare Divisions = 10;
	#declare Space = ( LEN - ( Divisions * 2 ) ) / ( Divisions + 1 );
	#declare Count = 0;
	union{
		#while( Count < Divisions )
			box{
				<Space + Count * ( Space + 2 ),5,-20>, 
				<Space + Count * ( Space + 2 ) + 2,6,20>
			}
			#declare Count = Count + 1;
		#end
	}
	texture{
		pigment{ P_Chrome5 }
		finish{ F_MetalA }
	}
}

plane{
  y, 0
  pigment{ checker Green White }
}