#version unofficial MegaPov 0.7; // Actually ML-POV

global_settings { assumed_gamma 1
	radiosity {
	 pretrace_start 0.08
      pretrace_end   0.01
      count 400
      nearest_count 7
      error_bound 0.3
      recursion_limit 1
      low_error_factor 0.75
      gray_threshold 0
      minimum_reuse 0.017
      brightness 1.7
      adc_bailout 0.01/2 }
}

#default { finish { ambient 0 brilliance 1+(1^2.2) } }

// Camera with focal blur
camera { location <0,2,-4>*1.3 look_at 0 angle 48
	aperture .3 blur_samples 31 variance .00001 confidence .90 focal_point 0
}

// Dim light_sources placed where the HDR image is brightest, to give specular highlights
light_source { <-60,40,-23>,<.052,.051,.04>*2
	area_light x*24,y*24,2,2 adaptive 1 circular orient jitter
}
light_source { <-58,16,-25>,<.052,.051,.04>*3
	area_light x*24,y*24,2,2 adaptive 1 circular orient jitter
}
light_source { <-70,4,-27>, <.052,.051,.04>*2 }


// Ground
plane { y,-1 hollow
	pigment { image_map { tga "d:\textures\concrete\plaster21.tga" interpolate 2 }
		translate .5 rotate 90*x scale <640,1,480>/28 }
	normal { granite .2 scale .6 } finish { diffuse .2 brilliance .8 reflection .06 }
}


// Texture to the black sphere
#local Metal_Pigment_Finish=texture {
	pigment { rgb .1*z }
	finish { reflection .29 diffuse .05 brilliance 4 metallic reflection_exponent .85 }
}

#local Metal=texture { average texture_map {
	#local Count=0;
	#while(Count<7) // Blur samples 0 - 255
		[1 Metal_Pigment_Finish normal { bumps .6 scale 1000 translate Count*130 } ]
		#local Count=Count+1;
	#end
}}


// The 3 spheres in the scene
sphere { 0,.4 translate <-1.3,-.6,-1> texture { Metal } }

sphere { 0,1 pigment { rgb .6 } finish { specular 1 roughness .03 } }

sphere { 0,.4 translate <1.3,-.6,-1>
	pigment { rgb <.6,.3,.28>*2 } finish { specular 1 roughness .03 diffuse .3 }
	normal { granite .33 scale .15 }
}

// Sky sphere (enviroment)
sphere { 0,500 hollow finish { diffuse 0 ambient .2 }
	pigment { image_map { hdr "f:\programmer\POV-Ray\hdr\beach_probe.hdr" interpolate 2 map_type 7 }
	}
}