// Persistence of Vision Ray Tracer Scene Description File
// File: Isotest3.pov
// Vers: 3.5
// Desc: Isosurface trig function texture experiments
// Date: 10-Mar-2002
// Auth: Charles W. Shults III
//

#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <7, 8, -27.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <2, 1.0,  0.0>
}

sky_sphere {
  pigment {
    bozo
    scale .05
    turbulence .6
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.4 rgb <0.0,0.1,0.8>]
      [1.0 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-30, 30, -30>
}

// ----------------------------------------

plane {
  y, -7
  pigment { color rgb <0.7,0.5,0.3> }
}

box {<-100,-10,40><100, 8,41> pigment {granite} finish {roughness .5}}

// note about this function- keep x and y small for foliage shape and z large for granularity

#declare Foliage1 = isosurface {
  function {sin(cos(x*.7) + sin(y*.8)+cos(z*15))}
  contained_by { sphere{0,2.3} }
  accuracy 0.001 
  max_gradient 4
  max_trace 6 
  open
  pigment {color Green}
  finish {roughness .3 ambient .02}
  scale 2
}

#declare SmallTree = union {
object {Foliage1
  clipped_by {
    sphere {0,3}
    }
  rotate 180*x
  scale 2
  }
  cylinder {<0,2.5,0> <0,-7,0> .3 pigment {color Brown} finish {roughness .5} normal {crackle scale .1}}
}

object {SmallTree translate <-8,0,10>}
object {SmallTree rotate 45*y translate <-1,0,20>}
object {SmallTree rotate -30*y translate <7,0,30>}
object {SmallTree rotate -145*y translate <15,0,10>}

// end