// Persistence of Vision Ray Tracer Scene Description File
// File: CrystalBall.pov
// Vers: 3.5 / MegaPov 1.0
// Desc: A crystal ball on a silver stand
// Date: 2-15-03
// Auth: Anthony D. Baye

#version unofficial MegaPov 1.0;

#include "kolors.inc"
#include "textures.inc"
#include "Book.inc"
#include "functions.inc"

#declare ft = 12 ;

#declare Leg =
difference {
	difference {
		cylinder { <0.0, -0.03125*ft, 0.0> <0.0, 0.03125*ft, 0.0> 2.5*ft }
		cylinder { <0.0, -0.0625*ft, 0.0> <0.0, 0.0625*ft, 0.0> 2.375*ft }
		box { <0.0, -0.0625*ft, -2.625*ft> <-2.625*ft, 0.0625*ft, 2.625*ft> }
			rotate -90.0*x
			translate <-2.5625*ft, 1.0*ft, 0.0>
		}
	box { <-2.625*ft, -2.625*ft, -0.0625*ft> <0.0625, 0.03125*ft, 0.0625*ft> }
	box { <-2.625*ft, 2.9125*ft, -0.0625*ft> <0.0625, 4.625*ft, 0.0625*ft> }
			rotate 90.0*y
	}


#declare Table =
	union {
		cylinder { <0.0, 2.9125*ft, 0.0> <0.0, 3.0*ft, 0.0> 2.5*ft }
		cylinder { <0.0, 0.0, 0.0> <0.0, 0.03125*ft, 0.0> 0.75*ft }
		difference {
			cylinder { <0.0, 0.0, 0.0> <0.0, 0.03125*ft, 0.0> 1.125*ft }
			cylinder { <0.0, -0.0155125, 0.0> <0.0, 0.0625*ft, 0.0> 0.75*ft }
			cylinder { <2.25*ft, -0.0155125, 0.0> <2.25*ft, 0.0625*ft, 0.0> 2.0*ft }
			cylinder { <-2.25*ft, -0.0155125, 0.0> <-2.25*ft, 0.0625*ft, 0.0> 2.0*ft }
			}
		difference {
			cylinder { <0.0, 0.0, 0.0> <0.0, 0.03125*ft, 0.0> 1.125*ft }
			cylinder { <0.0, -0.0155125, 0.0> <0.0, 0.0625*ft, 0.0> 0.75*ft }
			cylinder { <2.25*ft, -0.0155125, 0.0> <2.25*ft, 0.0625*ft, 0.0> 2.0*ft }
			cylinder { <-2.25*ft, -0.0155125, 0.0> <-2.25*ft, 0.0625*ft, 0.0> 2.0*ft }
				rotate 90.0*y
			}
	#declare Leg_Count = 0.0 ;
	#while (Leg_Count < 360)
		object { Leg rotate Leg_Count*y }
	#declare Leg_Count = Leg_Count + 72.0 ;
	#end
		torus { 0.25*ft, 0.5 translate 0.9125*ft*y }
		torus { 1.125*ft, 0.5 translate 2.9125*ft*y }
		torus { 0.5*ft, 0.5 translate 0.03125*ft*y }
			pigment { DMFDarkOak turbulence 0.8 scale 4 }
			finish { ambient 0.2 diffuse 0.375 phong 0.625 phong_size 50 reflection { 0.05 fresnel on } conserve_energy }
		}

#macro WriteClothFile(filename, n1, n2, nlng, ks, ht)
#debug "\nWriting new cth file\n"
#fopen file filename write
#write(file, n1, ", ", n2, ", ",nlng, ", ", ks, ",\n")
#local l1 = nlng*(n1-1);
#local l2 = nlng*(n2-1);
#local st = seed(1980);
#local i=0;
#while (i < n1)
#local j=0;
#while (j <n2)
#local tempx = -l1/2 + i*nlng;
#local tempz = -l2/2 + j*nlng;
#local tempy = ht + (-1+2*rand(st))*nlng*0.1;
#write(file, tempx, ",", tempy, ",",tempz, ", 0.0, 0.0, 0.0,\n")
#set j=j+1;
#end
#set i=i+1;
#end
#fclose file
#end

WriteClothFile("TCloth.cth", 50, 50, 96/50, 8.0*ft, 3.5*ft) 

simcloth {
	environment Table
	viscosity 1.0
	friction 0.5
	gravity -1.0*ft*y
	damping 0.9
	intervals 0.04
	iterations 3500
	input "TCloth.cth"
	output "TCloth.cth"
	mesh_output "TCloth.msh"
	smooth_mesh on
	uv_mesh on
	}

#declare TableCloth =
mesh {
	#include "TCloth.msh"
	uv_mapping
	texture {
		pigment { color rgb <0.25, 0.0, 0.0> }
		finish {
			reflection {
				rgb <1.0, 1.0, 1.0>
				exponent 0.05
				fresnel on
				}
			irid { 0.25 thickness 0.5 turbulence 0.8 }
			diffuse 0.6
			brilliance 1.0
			phong 0.3125
			phong_size 5
			specular 0.375
			roughness 0.025
			} 
		}
	}

camera {
	location  <0.0 , 6.0*ft , -7.5*ft>
	look_at   <0.0 , 3.25*ft , 0.0>
	}

object { light_source { <5.0*ft, 10.0*ft, -7.5*ft> color rgb 1.0 } }

object {
	union {
		plane { y, 0 }
		plane { y, 12.0*ft }
	#local A = 0.0 ;
	#while(A < 360)
		plane { -x, -12.0*ft rotate A*y }
	#local A = A + 90.0 ;
	#end
		}
		pigment { checker color Blue color White scale ft }
	}


object { Table }
object { TableCloth }