// Persistence of Vision Ray Tracer Scene Description File
// File: phot_normal.pov
// Vers: 3.5
// Desc: photons and normal test scene
// Date: October 2001
// Auth: Christoph Hormann  
   
#version 3.5; 

#include "colors.inc"                      

global_settings { 
  assumed_gamma 1  
  max_trace_level 25  
        
  photons {
    spacing 0.005  
    autostop 0
    jitter 0
  }         
}                 
     
camera {                     
  location    <10, 3.0, 5>  
  right       (4/3)*x               
  look_at     <0.3, 0.5, -0.6>  
  angle       12
}         

light_source {    
  <-3, 3, 6>  
  color rgb <1.5, 1.4, 1.2>      
  
  photons {
    //reflection on 
    refraction on 
  }  
}
    
#declare Tex_X=    
  texture {
    pigment {
      color rgb <1.0, 0.8, 0.5>
    } 
    finish {
      diffuse 0.6
      ambient 0
    } 
  }  
   
box {
  <-3, -0.2, -3>, <3, 0.0, 3>      
  
  texture { Tex_X }
} 

sphere {
  <0.3, 0, -0.6>, 0.1    
  
  texture { Tex_X }
} 

box {
  -0.1, 0.1      
  translate <0.3, 0, -0.6>*1.6
  texture { Tex_X }
}  

cylinder { 
  <0,0.0001,0>, y, 0.3
    
  material {   
    texture {
      pigment { color rgbt 1 }
      finish { 
        ambient 0
        diffuse 0  
      } 
    }  
    interior {
      ior 1.0
    }
  }     
    
  photons { 
    target 
    refraction on 
    //collect off
  }
}