#include "colors.inc" 
#include "woods.inc"

#version unofficial MegaPov 0.6;        

global_settings{
	ini_option "+QR"
	radiosity {
		recursion_limit 5 
		brightness .7 
		normal on
	}        
}  

camera {
	location <0, 0, 0>
	look_at <0, 0, 1>
	up <0, 1, 0>
	right <4/3, 0, 0>  
}

background { color rgb 1 }    
         
light_source { <3, 40, 3> color rgb .5 }  
light_source { <-10, 40, 13> color rgb .5 }
light_source { <3, 40, 13> color rgb .5 }

#declare Streifen = union {
	cylinder { z*5, z*-5, .2 translate x*-.05 }
	cylinder { z*5, z*-5, .2 translate x*.05 }
	box { <-.05, -.2, -5>, <.05, .2, 5> }
}          

#macro RotatedText(Txt, Size, Radius, Angel)
	text {  
		ttf "C:\Windows\Fonts\arial.ttf" 
		Txt
		1, 0        
		align_center             
		
		rotate x*90
		scale <Size, 1, Size>
		translate z*Radius
		
		rotate y*Angel
	}
#end

#declare Reifen = union {   
	difference {
		cylinder { 0, y*-4, 10 } 		
		cylinder { y*.1, y*-.2, 5 }
		cylinder { y*.1, y*-4.1, 1 }    
		cylinder { y*-1, y*-4.1, 9.5 }    
		
		torus { 9.2, .3 translate y*-1 }
	}        
	
	union {  
		difference {
			union {
				cylinder { y*-1, y*-3.75, 2.5 }  
				cylinder { y*-1, y*-1.2, 4.5 }
			}
			cylinder { y*-.9, y*-4, 1 }  
			cylinder { y*-3.25, y*-4, 1.5 }
		}   		                                   
		
		difference { 
			cylinder { y, 0, 3.5 }
			torus { 3.5, 1 }
			cylinder { y*1.1, y*-.1, 1.1 }
			
			translate y*-2.2
		}
	}
	
	torus { 9.75, .25 translate y*-4 }
	
	torus { 5, .2 translate y*-.2 } 
	
	difference {
		union {
			#local Count=0;
			#while (Count<4)
				union {
					object { Streifen translate x*-1.75 }
					object { Streifen translate x*-1.75 rotate y*120 }
					object { Streifen translate x*-1.75 rotate y*-120 }
					rotate y*30*Count
				}       
				#local Count=Count+1;
			#end			
			translate y*-.2
		}
		cylinder { y*.1, y*-.4, 1.6 }
	}   
	 
	intersection {
		torus { 8, 1.9 scale <1, .5, 1> translate y*-.05 }
		union {  
			union {
				object { RotatedText("B", 2.7, 6.75, -15) } 
				object { RotatedText("S", 2.7, 6.75, 0) }
				object { RotatedText("A", 2.7, 6.75, 15) }
			}
			
			union {
				object { RotatedText("P", 2.7, -8.8, 80) } 	
				object { RotatedText("I", 2.7, -8.8, 70) } 
				object { RotatedText("N", 2.7, -8.8, 60) }
				object { RotatedText("E", 2.7, -8.8, 47) }
				object { RotatedText("W", 2.7, -8.8, 30) }
				object { RotatedText("O", 2.7, -8.8, 13) }
				object { RotatedText("O", 2.7, -8.8, -2) }
				object { RotatedText("D", 2.7, -8.8, -17) }  
				
				object { RotatedText("D", 2.7, -8.8, -40) }
				object { RotatedText("E", 2.7, -8.8, -54) }
				object { RotatedText("R", 2.7, -8.8, -68) }
				object { RotatedText("B", 2.7, -8.8, -82) }
				object { RotatedText("Y", 2.7, -8.8, -96) } 
				
				object { RotatedText("T", 1.5, -8.5, -105) }
				object { RotatedText("M", 1.5, -8.5, -113) }      
				
				rotate y*10
			}
		
			translate y*.91
		}    
	} 
	
	
	
	intersection {
		torus { 8, 1.9 }    
		cylinder { 0, y*2, 10 }  
		scale <1, .5, 1>    
		translate y*-.1
	}   
	
	#local Count=0;
	#while (Count<360)       
		sphere { <9.8, .05, 0>, .15 rotate y*Count }
		#local Count=Count+2;
	#end
	
	texture
      {
         pigment
         {
            color rgb <0.239567, 0.239567, 0.1979>
         }
         normal
         {
            bumps , 0.05
            bump_size 0.05
         }
         finish
         {
            ambient 0.0
            diffuse 0.1007
            brilliance 3.909667
            phong 0.165467
            phong_size 30.463333
            specular 0.194233
            roughness 0.3308
            reflection 0.0275
            crand 0.0935
         }
      }            
	   /*
	texture {
		pigment { rgb .3 }  
		finish {  
			ambient .3
			phong .3
			phong_size 3
			reflection .1
			crand .01
		}	
		normal {
			bumps .1
			scale .001
		}	
	}    */
}                           
                    /*
object { 
	Reifen             
	texture {
		pigment { rgb .3 }  
		finish {  
			ambient .3
			phong .3
			phong_size 3
			reflection .1
			crand .01
		}	
		normal {
			bumps .1
			scale .001
		}
	
	}
	
	rotate x*120
	translate <0, 2, 25>
}                 */

#declare Szene = union {
	object { Reifen }
	object { Reifen rotate x*180 translate <22, -4, 0> }
	
	plane {
		y, 0
		
		texture { 
			T_Wood10
			finish {
				reflection .1
			} 
			
			scale 3
		}
		
		translate y*-4
	}
	
}        

object {
	Szene  
	rotate y*-20 
	rotate x*-40 
	
	translate x*-7
	translate z*30
	
}