#version unofficial MegaPov 0.6;

#include "colors.inc"
#include "skies.inc"

#declare with_radiosity = true; // or false

global_settings
{
	max_trace_level 32
	#if (with_radiosity = true)
		ambient_light 0.01
		ini_option "+QR"
		radiosity
		{
			pretrace_start 0.08
			pretrace_end 0.02
			count 50
			nearest_count 5
			error_bound 1
			recursion_limit 3
			low_error_factor .5
			gray_threshold 0.0
			minimum_reuse 0.015
			brightness 1
			adc_bailout 0.01/2
			normal on
		}
	#end
}

sky_sphere {S_Cloud2}

camera
{
	location <-2,7,-6>*.5
	look_at 0
	angle 37
}

#declare do_area_lights = 10;
#declare main_light_size = 0.2;

light_source
{
	<10,20,-10>/7, 1 
 	#if (do_area_lights > 1)
		area_light
		<main_light_size, 0, 0> <0, main_light_size, 0>
		do_area_lights, do_area_lights
		adaptive 0
		jitter
		circular
		orient 
	#end
}

#declare GoldBase = <1.00, 0.875, 0.575>;
#declare CVect2 = GoldBase - <0.00, 0.15, 0.30>;
#declare P_Gold2 = rgb CVect2;
#declare P_Silver2 = color rgb <0.94, 0.93, 0.85>;

#declare my_v0 = 0.25;
#declare my_v1 = 0.353 * 4 * my_v0;
#declare my_v2 = 0.288 * 4 * my_v0;

#declare HF = function
{
	pigment
	{
		julia <my_v1 , my_v2> 30
		color_map
		{
			[0 rgb 0]
			[1 rgb 1]
		}
		fractal_interior_type 1,2
	}
}

isosurface
{
	function
	{
		z-HF(x,y,z)^.25/2
	}
	accuracy .0001
	max_gradient 4
	contained_by
	{
		box
		{
			<-3,-3,-.001> <3,3,1>
		}
	}
	pigment
	{
		julia <my_v1 , my_v2> 30
		fractal_interior_type 1,2
		color_map
		{
			[0 P_Gold2  ]
			[1 P_Silver2]
		}
	}
	finish
	{
		ambient 0.25
		brilliance 4
		diffuse 0.5
		metallic
		specular 0.80
		roughness 1/80
		reflection 0.25
	}
	rotate x*-90
	rotate y*90
}