/*
 Example of an I-beam (aka RSJ Girder)
 Martin 09/07/00
 ml_pov@ml1.co.uk
 
 Note: Make sure the font used for the "I" is 
       present within a library path (+L) if not 
       using the standard POVRay installed fonts.
       
       eg for Windows: +Lc:\windows\fonts
*/

#include "colors.inc"

background{ Med_Purple*0.5 }

camera{
  location <0,4,-11>
  angle 80
  look_at <0,-1,0>
}

light_source{
  <5, 11, -22>
  color White
  }

light_source{
  <0,15,-18>
  color White
  fade_power 1.75
  fade_distance 23
  }


// Declare the I-Beams, normailsed to fit into
// a 1 unit cube centred at <0,0,0>.
// The beam extends along the z axis.
// (RSJ: Rolled Steel Joist)

#declare IBeam1 = // Standard rounded cross-section RSJ/Girder/Beam
  object{
    text{ ttf "timrom.ttf" "I", 1, 0 }
    scale <3.45,1.475,1>
    translate <-0.5,-0.5,-0.5>
  }
  
#declare IBeam2 = // Square cross-section RSJ/Girder/Beam
  object{
    text{ ttf "crystal.ttf" "I", 1, 0 }
    scale <3.85,1.475,1>
    translate <-0.5,-0.5,-0.5>
  }
  
#declare IBeam3 = // Thick shouldered girder with thin centre web
  object{
    text{ ttf "crystal.ttf" "H", 1, 0 }
    scale <2.96,1.475,1>
    translate <-0.5,-0.5,-0.5>
    rotate 90*z
  }
  

// Show a few examples

#declare ExampleBeams =
  union{
    object{ IBeam1
      scale <0.5, 1, 9>
      translate -2*x
    }
    object{ IBeam2
      scale <0.5, 1, 9>
      translate 0
    }
    object{ IBeam3
      scale <0.5, 1, 9>
      translate 2*x
    }
  }
  
   
object{
  ExampleBeams
  scale <1,1,1.5>
  texture{
    pigment{SteelBlue}
    finish{reflection 0.1  phong 1  phong_size 40}
    normal{dents 0.2  scale 0.09}
    }
}

union{
  object{
    ExampleBeams
    rotate 40*y
    translate y
  }
  intersection{  // Put a 45 degree mitre at one end
    object{ExampleBeams}
    plane{-z,0
      pigment{Green} 
      rotate 45*x
      translate 2*z
    }
    rotate <90,180,0>
    translate <0,6,-4>
    rotate 40*y
  }
  texture{
    pigment{Brown}
    finish{reflection 0.1  phong 1  phong_size 40}
    normal{bumps 0.07  scale 0.08}
  }
}

object{
  ExampleBeams
  rotate 90*x
  translate <0,1,5>
  rotate 40*y
  texture{
    pigment{Bronze}
    finish{reflection 0.1  phong 1  phong_size 40}
    normal{wrinkles 0.1  scale 0.07}
  }
}


// A boring POV-plane

plane{y, -0.5
  texture{
    pigment{hexagon Red*0.5, Green*0.5, Blue*0.5}
    finish{ reflection 0.5} 
  }
  rotate 11*y
}