// Cover for CD -- Circa 1992
      
#include "colors.inc"
#include "textures.inc"

camera {
    location <0,5,0>+<0,0,-5*2>
    direction <0,0,1.5*2>
    right <2,0,0>
    up <0,1,0>
    look_at <0,5,0>
    }

light_source {
    <-2000,30000,10000> color White
    }

// sky
object {
    sphere {<0,0,0>,50000 inverse}
    texture {
        pigment {
            gradient y
            scale 60000
            color_map {
                [0 color rgb<.3,.3,1>]
                [0.25 color rgb<.6,.6,1>]
                }
            }
        finish {ambient 1 diffuse 0}
        }
    }

// sand
light_source {<0,5,0>+<0,0,-5*2> color White}
#declare F1=function{cos(x+abs(sin(x*2)))}
#declare F2=function {
      y-(
        (F1(sqrt(sqr(x+50)+sqr(z-15))*30+noise3d(x,z,y/10)*5,0,0)+1.1)
        +(cos(sqrt(sqr(x+10)+sqr(z+30))*15+noise3d(x,z,y/10)*10)+1)
        )/8
      }

isosurface {
    function {F2(x,y,z)}
    method 2
    max_gradient 10
    accuracy 0.001
    normal
    bounded_by {box {0,1}}
    translate -0.5
    scale <500,40,500>
    scale .2
    translate <-7.5,0,-5>
    translate y*7.75
    texture {
        pigment {
            granite
            color_map {
                [0 color rgb <1,0.8,0.5>]
                [1 color rgb <1.1,0.9,0.7>]
                }
            scale 10
            }
        finish {diffuse 0.8}
        normal {bumps 0.2 scale 0.02}
        }        
    }
    
object {
    merge {
        intersection {
            cylinder {<0,0,-0.005>,<0,0,0.005>, .25}
            cylinder {<0,0,-1>,<0,0,1>,(1/48) open inverse}
            texture {
                Glass
                finish {ior 1.1}
                }
            }
        intersection {
            cylinder {<0,0,-0.006>,<0,0,0.006>, .24}
            cylinder {<0,0,-1>,<0,0,1>,(1/24) open inverse}
            texture {
                Chrome_Texture
                pigment {
                    radial
                    pigment_map {
                        [0.1 rgb<1,1,1>]
                        [0.2 rgb<2,0,0>]
                        [0.25 rgb<2,1.5,0>]
                        [0.275 rgb<1.2,1.2,.4>]
                        [0.29 rgb<.6,1,.6>]
                        [0.3 rgb<1,1,1>]
                        [0.6 rgb<1,1,1>]
                        [0.625 rgb<.6,1,.6>]
                        [0.63 rgb<.4,1.2,1.2>]
                        [0.65 rgb<0,0,2>]
                        [0.7 rgb<1.5,0,2>]
                        [0.75 rgb<1,1,1>]
                        }
                    rotate <-90,0,0>
                    rotate <0,0,90>
                    }
                }
            }
        }
    rotate <0,-20,0>
    rotate <40,0,0>
    translate <2.5,4,-0.5>
    }

#declare mcmxcii=text {ttf "C:\Windows\Fonts\Times.ttf" "MCMXCII" 0.1,0 scale <0.25,0.25,1>}

object {
    intersection {
        box {<-0.75,-0.375,-0.25>,<0.75,0.375,0.25>}
        object {
            mcmxcii
            inverse
            translate <-max_extent(mcmxcii).x/2,-max_extent(mcmxcii).y/2,-0.3>
            texture {
                pigment {color rgb <0.6,0.5,0.4>}
                normal {bumps 0.5 scale 0.01}
                finish {ambient 0.5 diffuse 0.2}
                }
            }
        bounded_by {box {<-0.751,-0.3751,-0.251>,<0.751,0.3751,0.251>}}
        }
    texture {
        pigment {color rgb <0.6,0.5,0.4>}
        normal {bumps 0.5 scale 0.01}
        finish {ambient 0.5 diffuse 0.7}
        }
    rotate <0,10,0>
    rotate <50,0,0>
    translate <1,4.25,1>
    }

object {
    intersection {
        plane {y+x,0 translate <0,120,0>}
        plane {y-x,0 translate <0,120,0>}
        plane {y+z,0 translate <0,120,0>}
        plane {y-z,0 translate <0,120,0>}
        plane {-y,0}
        }
    rotate <0,-20,0>
    translate <100,-20,750>
    texture {
        pigment {rgb <1,0.9,0.6>}
        finish {ambient 0.4}
        normal {bumps 0.5 scale 0.5}
        }
    }