#include "colors.inc"
#include "metals.inc"
#include "golds.inc"

// -----------------TEXTURES---------------
#declare Tx1=texture {
	T_Gold_5D
	normal {
		granite .35
		turbulence .25
		frequency 5
	}
	scale 2.111
}

#declare Tx2=texture {
	T_Chrome_2A
	normal {
		bumps .81
		turbulence .77
	}
	finish {
		reflection 0.1
		metallic
	}
	scale 2.21
}

#declare BaseTexture=texture {
	pigment { color White }
	finish { reflection 0.23 }
}

#declare RecursionTexture=texture {
	pigment { color Black }
	finish { reflection 0.43 }
}

#declare JoyTexture=texture {
	pigment {
		color rgb <24/255,107/255,165/255>
	}
	finish {
		reflection 0.6
	}
}

#declare MaterialTexture=texture {
	material_map {
		gif "joy.gif"
		interpolate 2
		texture { RecursionTexture }
		texture { JoyTexture }
	}
	rotate 90*x
}

// -----------------MACROS---------------
#macro RecText( iRecLevel,iScaleFraction,iBaseTexture,iRecTexture )
texture {
	checker
	texture { iBaseTexture }
#if (iRecLevel=0)
	texture { iRecTexture }
#else
	RecText( iRecLevel-1,iScaleFraction,iRecTexture,iBaseTexture )
	scale 1/iScaleFraction
#end
}
#end


plane {
	y, 0
	RecText( 2, 3, MaterialTexture, RecursionTexture )
}

camera
{
	location < 0.0, 2.0,-7.0>
	look_at < 0.0, 0.5, 0.0>
//	look_at < 0.0, 0.0,-7.0>
}

light_source
{
	< 0.0, 20.0, -20.0>
	color White
}

light_source
{
	< 20.0, 25.0, -25.0>
	color White
}

difference {
	plane {
		z, 0
		texture {
			material_map {
				gif "joy.gif"
				interpolate 2
				once
				texture { pigment { color rgbt <0,0,0,1> } }
				texture { Tx2 }
			}
			translate <-0.5,-0.03, 0.0>
			scale 3
		}
		bounded_by {
			box { <-1.5, 0.0,-0.01>,<1.5,3.0,0.01> }
		}
	}
	text {
		ttf "timrom.ttf"
		"High Tech Automation"
		0.1, 0
		scale 0.15
		translate <-0.2, 2.6,-0.01>
	}
	hollow
}


intersection {
	plane {
		z, 0
		texture {
			material_map {
				gif "joy.gif"
				interpolate 2
				once
				texture { JoyTexture }
				texture { pigment { color rgbt <0,0,0,1> } }
			}
		}
	}
	box {
		< 0.01,0.01,-0.01>, < 0.99,0.99,0.01>
		texture { pigment { color rgbt <0,0,0,1> } }
	}
	translate <-0.1,-0.03,-0.3>
	scale 3
	hollow
}


light_source {
	< 3,4,-3>,
	color White
	spotlight
	radius 15
	falloff 20
	point_at <0,1.5,-0.3>
}

/*
fog {
	fog_type 2
	color rgbt <1,1,1,0.3>
	distance 10
	fog_offset 0
	fog_alt 1
}
*/