#include "colors.inc"

global_settings
{
  photons
  {
    gather 20, 100
    radius 0.5, 3, 0.5
  }

  max_trace_level 25
}

sphere
{
  0, 0.75
  texture
  {
    pigment { Gray90 }
    finish { ambient 0.1 diffuse 0.9 brilliance 1.5 reflection 0.5 specular 0.5 roughness 0.005 phong 0.25 phong_size 8 }
    normal { leopard sine_wave frequency 0.25 phase 0.5 scale 0.05 }
  }
  no_shadow
  photons
  {
    reflection on
    density 0.02
  }
}    

union
{
  box { 0, .99 }
  box { <-0.99,0,-0.99>, <0,0.99,0> }
  box { <0,-0.99,-.99>, <0.99,0,0> }
  interior
  {
    media
    {
      absorption 1
      intervals 10
      samples 1, 10
      variance 1/255
      confidence 0.999
      scattering { 1, 2 extinction 0}
    }
  }  
  hollow
  pigment { Clear }
  photons { photons_pass_through }
}

camera
{
  location  <1.0 , 2.0 ,-3.0>*.85
  right x
  look_at   <-.15 , -.3 , 0.0>
}

light_source
{
  <10,10,10> color Red
  spotlight
  point_at 0
  radius 2
  falloff 5
  photons { reflection on }
}

light_source
{
  <-10,10,-10> color Blue
  spotlight
  point_at 0
  radius 2
  falloff 5
  photons { reflection on }
}

light_source
{
  <10,-10,-10> color Green
  spotlight
  point_at 0
  radius 2
  falloff 5
  photons { reflection on }
}