#include "colors.inc"
#include "metals.inc"
#include "stones.inc"
#include "woods.inc"


// no default radiosity   
//global_settings { ambient_light  Black  }

//background { Blue }

plane { y,0 texture { T_Wood1 } scale 4}

plane { x, -30 
        texture 
         { 
          brick texture { pigment { Black } }  , 
                texture { T_Stone8 }
          mortar 0.5
          brick_size <1,1,2>*5
         } 
      }

plane { z, 30 
        texture 
         { 
          brick texture { pigment { Black } }  , 
                texture { T_Stone8 }
          mortar 0.5
          brick_size <2,1,1>*5
         } 
      }


//light_source { <20,10,-5> color White }
//light_source { <-20,20,-5> color White }

//camera { location <20,10,-25> look_at <0,0,0> }
camera { location <20,10,-25>*0.4 look_at <0,2.5,0> }


////////////////////////////////////////////////
#declare Scale=
difference
 {
 
  prism
   {
    linear_sweep
    linear_spline
    0,0.5
    7,
    <0,0>,<1,1>,<1,4>,<0,5>,<-1,4>,<-1,1>,<0,0>
  
    rotate <-90,0,0>
  
   }
   
  union
   {
    sphere { 0 1  scale <1.25, 5, 0.95> translate <-1,5,-1> }
    sphere { 0 1  scale <1.25, 5, 0.95> translate <+1,5,-1> }
   }

  box { <-1,0,0> <+1,4,-1> rotate <12.5,0,0> translate <0,3,-0.5> }
 }
    

////////////////////////////////////////////////
#declare Paw=
 difference
  {
   union
    {
     sphere { 0, 1 }
     sphere { 0 0.3 translate < sqrt(2),0, sqrt(2)>/2}
     sphere { 0 0.3 translate <-sqrt(2),0, sqrt(2)>/2}
     sphere { 0 0.3 translate < sqrt(2),0,-sqrt(2)>/2}
     sphere { 0 0.3 translate <-sqrt(2),0,-sqrt(2)>/2}
     sphere { 0 0.3 translate <0,0,-1> }
    }
   box{ <-2,-1,-2>, <2,0,2> }
  }



////////////////////////////////////////////////////////////////
// body

//#declare HogTexture = texture { pigment { Green } }   
#declare HogTexture = texture { T_Silver_5E  finish { irid { 0.35 thickness .5 turbulence .5}} } 
#declare EyesTexture = texture { pigment { Red } }

#declare rayon = 5

// pattes
object { Paw translate <  sqrt(2),0, sqrt(2)>*(rayon/2) texture { HogTexture }}
object { Paw translate < -sqrt(2),0, sqrt(2)>*(rayon/2) texture { HogTexture }}
object { Paw translate <  sqrt(2),0,-sqrt(2)>*(rayon/2) texture { HogTexture }}
object { Paw translate < -sqrt(2),0,-sqrt(2)>*(rayon/2) texture { HogTexture }}

// body
difference 
 {
  sphere {0,rayon}
  box { <-rayon-0.1,-rayon-0.1,-rayon-0.1> <rayon+0.1, 0.5,rayon+0.1> }
  texture { HogTexture }
 }                        
 
// Face 
difference
 {
  cone { <0,2,-rayon+2> 2.9 <0,1,-rayon-3> 0 scale <1,0.75,1> }
  box { <-1,0,-rayon-3> <1,3,-rayon-2+0.5> }
  texture { HogTexture }
 }
 
// eyes
sphere { 0, 0.3 texture { EyesTexture } translate <-0.75,2.25,-rayon-0.5> }
sphere { 0, 0.3 texture { EyesTexture } translate <+0.75,2.25,-rayon-0.5> }

////////////////////////////////////////////////////////////////
// scales

#declare dapos = 15;
#declare dzpos = 0.5;
#declare c = 1;
#declare zpos = -rayon +0.5;

#while (zpos < rayon)

 #if (c=1) 
  #declare apos = -90+7.5;
  #declare lpos = +90-7.5;
  #declare c=0;
 #else  
  #declare apos = -75;
  #declare lpos =  75;
  #declare c=1;
 #end
 
 #while (apos<90)
        
  object
   {
    Scale
    scale 0.5    
    rotate <15,0,0> // tilt
    translate <0, sqrt(pow(rayon,2)-pow(zpos,2)), zpos> // translate
    rotate <0,0,apos> // rotate around main axis
    translate <0,0.5,0>
    
    texture { HogTexture }
   }  
  #declare apos = apos+dapos;  
 #end // apos
 #declare zpos = zpos + dzpos;
#end // zpos 


////////////////////////////////////////////////////////////////
// autre cochonneries dans le decor

object
 {
  #declare LampColor= White;
  #declare LampGranularity=2;
  #include "..\OtherIncludes\Table_lamp.inc"
  scale 8
  translate <-10,0,-10>
 }

/*
object
 {
  #declare ComputerScreenDisplay = "c:/user/testdata/images/screenshots/desktop7.tga"
  #declare ComputerScreenRadiance = 5;
  #declare ComputerScreenAngle = 10;
  #include "..\otherIncludes\ComputerScreen.inc"
  scale 16
  rotate <0,11,0>
  //translate <1.5,0,-1>
  translate <15,0,15> 
 }
 
#include "..\otherIncludes\keyboard.inc"

object
 {
  Keyboard
  scale 12
  rotate <0,-12,0>
  translate <20,0,-15>
 }
*/