#version unofficial MegaPov 0.6;

#include "colors.inc"
#include "skies.inc"

sky_sphere
{
	S_Cloud2
}

camera
{
	location <0,3.5,-3.5>
	look_at 0
	angle 35
	rotate <0, 360*clock, 0>
}

light_source
{
	<0,3,-3>, 1
	rotate <0, -360*clock, 0>
}

#declare GoldBase = <1.00, 0.875, 0.575>;
#declare CVect2 = GoldBase - <0.00, 0.15, 0.30>;
#declare P_Gold2 = rgb CVect2;
#declare P_Silver2 = color rgb <0.94, 0.93, 0.85>;

#if (clock < 0.5)
	#declare my_v0 = (2 * clock);
#else
	#declare my_v0 = 1 - ((clock - 0.5) * 2);
#end

#declare my_v1 = 0.353 * 3 * my_v0;
#declare my_v2 = 0.288 * 3 * my_v0;

#declare HF = function
{
	pigment
	{
		julia <my_v1 , my_v2> 30
		color_map
		{
			[0 rgb 0]
			[1 rgb 1]
		}
		fractal_interior_type 1,2
	}
}

isosurface
{
	function
	{
		z-HF(x,y,z)^.25/2
	}
	accuracy .0001
	max_gradient 4
	contained_by
	{
		box
		{
			<-3, -3, 0.1> <3, 3, 2>
		}
	}
	pigment
	{
		julia <my_v1, my_v2> 30
		fractal_interior_type 1,2
		color_map
		{
			[0 P_Gold2]
			[1 P_Silver2]
		}
	}
	finish
	{
		ambient 0.25
		brilliance 4
		diffuse 0.5
		metallic
		specular 0.80
		roughness 1/80
		reflection 0.25
	}
	rotate x*-90
}

#declare Marble1 = pigment
{
	marble
	color_map
	{
		[0 rgb .5]
		[1 rgb .6]
	}
	turbulence .6
	scale .3
}

#declare Marble2 = pigment
{
	marble
	color_map
	{
		[0 rgb .9]
		[1 rgb 1]
	}
	turbulence .8
	scale .3
}

#declare fnBevel = function
{
	pigment
	{
		gradient x
		colour_map
		{
			[0 rgb 0.03]
			[0.03 rgb 0]
			[0.97 rgb 0]
			[1 rgb 0.03]
		}
	}
}

isosurface
{
	function
	{
		y + max(fnBevel(x,0,0), fnBevel(z,0,0))
	}
	contained_by
	{
		box
		{
			-<10,0.1,10>, <10,0.1,10>
		}
	}
	eval
	texture
	{
		pigment
		{
			checker
			pigment
			{
				Marble1
			},
			pigment
			{
				Marble2
				rotate <30,50>
			}
		}
		finish
		{
			specular .75
			reflection .5
		}
	}
	scale <0.5, 1 , 0.5>
	translate <0, 0.1, 0>
}