//Bug report: FBM_Clouds
//----------------------
//I often used the texture FBM_Clouds in my pictures, and with version 3.1 of POV-Ray I saw that
//the texture was wrong (this errors also appear in ShadowClouds, because it uses FBM_Clouds).
//I just created a texture named Old_FBM_Clouds in my textures.inc, and everything was good.
//I thought someone would also recognize this and correct it. But as I downloaded the new version
//3.5 beta, I recognized the same error. So now I report this bug and hope it will be fixed in
//the final version 3.5 or in version 4.0
//This scene demonstrates the bug. It shows a blob consisting of 3 spheres. The left sphere is
//created with FBM_Clouds from version 3.0, the middle sphere with the actual FBM_Clouds texture
//from version 3.5 and the right sphere is created with a corrected texture I created to give you
//an example how it COULD be.
//There is also a sphere in the upper part showing the FBM_Clouds texture in YOUR POV-Ray version.
//And, of course, there is the standard green/yellow checker ground (to demonstrate the transparency
//of the textures).
//
//POV-Ray version  : 3.1 and 3.5
//Operating system : Windows 98
//Processor        : AMD K6-3 with 400 MHz
//Memory           : 64 MB RAM
//
//Christian Schneider (Schnader1@compuserve.de)


//This bug does happen with version 3.1 and 3.5 beta, doesn't happen with version 3.0 and older
#version 3.5;

#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"

camera{
 location <0,0,-10>
 right 4/3*x
 up y
 look_at <0,0,0>  
}

//Old FBM_Clouds (Version 3.0 and older) - part of "textures.v2" version 3.0

#declare Old_FBM_Clouds =
pigment {
    bozo
    turbulence 0.65
    octaves 6
    omega 0.7
    lambda 2
    color_map { 
        [0.0, 0.1   color red 0.85 green 0.85 blue 0.85 
                    color red 0.75 green 0.75 blue 0.75] 
        [0.1, 0.5   color red 0.75 green 0.75 blue 0.75 
                    color Clear] 
        [0.5, 1.001 color Clear color Clear] //can be deleted (can't it?)
    } 
 scale <6, 1, 6>
}

//Actual FBM_Clouds (first seen in version 3.1, also in version 3.5) - part of "textures.inc" version 3.5
//The first entrys of the color maps are just shorter than the old, but
//the last entrys (see comments) are wrong.

#declare Actual_FBM_Clouds =
pigment {
    bozo
    turbulence 0.65
    octaves 6
    omega 0.7
    lambda 2
    color_map { 
        [0.0 rgb 0.85]
        [0.1 rgb 0.75] 
        [0.5 rgb 0.75]       //should be [0.5 rgbt <1,1,1,1>]
        [0.5 rgbt <1,1,1,1>] //should be [1.0 rgbt <1,1,1,1>], can also be deleted
    } 
scale <6, 1, 6>
}

//Corrected FBM_Clouds (for example)
//I don't know why "Clear" (which is rgbf 1) was replaced by "rgbt <1,1,1,1>" (which is rgbt 1)
//but I will use "rgbt 1" in the corrected version. I also deleted the entry 1.0 of the color_map
//because it works without it (doesn't it?).

#declare Corrected_FBM_Clouds =
pigment {
    bozo
    turbulence 0.65
    octaves 6
    omega 0.7
    lambda 2
    color_map { 
        [0.0 rgb 0.85]
        [0.1 rgb 0.75] 
        [0.5 rgbt 1] 
    } 
 scale <6, 1, 6>
}

blob {
 threshold 0.6
 sphere {<0,0,0>,3,1 texture {Old_FBM_Clouds scale 0.8} translate <-3.75,0,0>}
 sphere {<0,0,0>,3,1 texture {Actual_FBM_Clouds scale 0.8} translate <0,0,0>}
 sphere {<0,0,0>,3,1 texture {Corrected_FBM_Clouds scale 0.8} translate <3.75,0,0>}
}

sphere {<0,0,0>,1.5 texture {FBM_Clouds scale 0.8} translate <0,3,0>}

plane {y,-3 pigment {checker color Green color Yellow}}

light_source {<0,0,-10> color White*2}