POV-Ray : Newsgroups : povray.advanced-users : HDRI starfield Server Time
29 Mar 2024 11:55:02 EDT (-0400)
  HDRI starfield (Message 1 to 7 of 7)  
From: Mike Horvath
Subject: HDRI starfield
Date: 10 Jan 2021 03:18:52
Message: <5ffab86c$1@news.povray.org>
Can anyone recommend an HDRI starfield texture that works with POV-Ray? 
I haven't used HDRI ever before so I don't know what to look for. Thanks!


Michael


Post a reply to this message

From: Robert McGregor
Subject: Re: HDRI starfield
Date: 25 Jan 2021 12:25:01
Message: <web.600efd3bd6c0391287570eab0@news.povray.org>
Mike Horvath <mik### [at] gmailcom> wrote:
> Can anyone recommend an HDRI starfield texture that works with POV-Ray?
> I haven't used HDRI ever before so I don't know what to look for. Thanks!

You didn't mention the context so I don't know what the starfield would be used
for, but there are some nice HDRIs at https://hdrihaven.com/hdris/ and even a
few with night skies.

If you just need something for a backdrop here's a simple noise-based texture
that might do the trick:

//------------------------------------------------------------------------------
// Stars and Nebula
//------------------------------------------------------------------------------

#declare T_StarField = texture {
   pigment {
      average
      pigment_map {
         [2
            bumps
            color_map {
               [0 rgb 0]
               [0.925 rgb 0]
               [1 srgb 0.6] // white (with emission)
            }
            scale 1/2
         ]
         [2
            bumps
            color_map {
               [0 rgb 0]
               [0.925 rgb 0]
               [1 srgb 0.65] // white (with emission)
            }
            scale 1/3
         ]
         [1.5
            bumps
            color_map {
               [0 rgb 0]
               [0.95 rgb 0]
               [1 srgb <0.75,0.75,0>] // yellow
            }
            scale 1/4
         ]
         [0.5
            bumps
            color_map {
               [0 rgb 0]
               [0.95 rgb 0]
               [1 srgb <0.75, 0, 0>] // red
            }
            scale 1/8
         ]
         [0.5
            bumps
            color_map {
               [0 rgb 0]
               [0.95 rgb 0]
               [1 srgb <0, 0, 0.75>] // blue
            }
            scale 1/8
         ]
         [0.5
            bumps
            color_map {
               [0 rgb 0]
               [0.925 rgb 0]
               [1 srgb 0.6] // white (with emission)
            }
            scale 1/16
         ]
      }
   }
   finish { emission 15 }
}

#declare T_Nebula = texture {
   pigment {
      bozo
      turbulence 0.75
      scale 0.125/2
      color_map {
         [0 rgbt 1]
         [0.7 rgbt 1]
         [0.8 srgbt <1, 0, 0.5, 0.75>]
         [0.9 srgbt <0, 0, 2.5, 0.75>]
         [1.0 srgbt <0, 2, 0, 0.75>]
      }
      omega 0.65
      lambda 3
      octaves 5
      scale 10000*4
   }
   finish { emission 0.0035 }
}


//------------------------------------------------------------------------------
// Stars and Nebula
//------------------------------------------------------------------------------

sphere { 0, 10000
   texture { T_StarField scale 10 }
   texture { T_Nebula scale 1 }
   texture { T_Nebula scale 1.5 rotate 45 }
   rotate 180
}

Cheers,
Rob


Post a reply to this message

From: Mike Horvath
Subject: Re: HDRI starfield
Date: 25 Jan 2021 18:03:42
Message: <600f4e4e$1@news.povray.org>
On 1/25/2021 12:19 PM, Robert McGregor wrote:
> Mike Horvath <mik### [at] gmailcom> wrote:
>> Can anyone recommend an HDRI starfield texture that works with POV-Ray?
>> I haven't used HDRI ever before so I don't know what to look for. Thanks!
> 
> You didn't mention the context so I don't know what the starfield would be used
> for, but there are some nice HDRIs at https://hdrihaven.com/hdris/ and even a
> few with night skies.
> 

Ah, sorry. I meant for an Outer Space scene. Those are all ground-based 
photographs.


> If you just need something for a backdrop here's a simple noise-based texture
> that might do the trick:
> 

Yeah, I'm using that. But you can tell they aren't point sources but are 
blobb-ish smudges.


Mike


Post a reply to this message

From: m@b
Subject: Re: HDRI starfield
Date: 26 Jan 2021 06:17:09
Message: <600ffa35@news.povray.org>
On 10/01/2021 4:18 pm, Mike Horvath wrote:
> Can anyone recommend an HDRI starfield texture that works with POV-Ray? 
> I haven't used HDRI ever before so I don't know what to look for. Thanks!
> 
> 
> Michael

Not HDRI, but if you want to place actual objects as stars take a look 
at BrightStar5 in the POV-Ray objects collection.
<http://lib.povray.org/searchcollection/index.php>

I used it in the opening sequence of this animation:
<https://youtu.be/GyqQolOK_qI>

m@


Post a reply to this message

From: Mike Horvath
Subject: Re: HDRI starfield
Date: 26 Jan 2021 17:37:04
Message: <60109990$1@news.povray.org>
On 1/26/2021 6:17 AM, m@b wrote:
> On 10/01/2021 4:18 pm, Mike Horvath wrote:
>> Can anyone recommend an HDRI starfield texture that works with 
>> POV-Ray? I haven't used HDRI ever before so I don't know what to look 
>> for. Thanks!
>>
>>
>> Michael
> 
> Not HDRI, but if you want to place actual objects as stars take a look 
> at BrightStar5 in the POV-Ray objects collection.
> <http://lib.povray.org/searchcollection/index.php>
> 
> I used it in the opening sequence of this animation:
> <https://youtu.be/GyqQolOK_qI>
> 
> m@

Thank you!

The problem is that I use 1 meter resolution, and numbers in POV are not 
64 bit.


Mike


Post a reply to this message

From: Alain Martel
Subject: Re: HDRI starfield
Date: 27 Jan 2021 11:33:24
Message: <601195d4$1@news.povray.org>
Le 2021-01-26 à 17:37, Mike Horvath a écrit :
> On 1/26/2021 6:17 AM, m@b wrote:
>> On 10/01/2021 4:18 pm, Mike Horvath wrote:
>>> Can anyone recommend an HDRI starfield texture that works with 
>>> POV-Ray? I haven't used HDRI ever before so I don't know what to look 
>>> for. Thanks!
>>>
>>>
>>> Michael
>>
>> Not HDRI, but if you want to place actual objects as stars take a look 
>> at BrightStar5 in the POV-Ray objects collection.
>> <http://lib.povray.org/searchcollection/index.php>
>>
>> I used it in the opening sequence of this animation:
>> <https://youtu.be/GyqQolOK_qI>
>>
>> m@
> 
> Thank you!
> 
> The problem is that I use 1 meter resolution, and numbers in POV are not 
> 64 bit.
> 
> 
> Mike

That should not be a problem. The various background constructions tend 
to be scale independent.

In POV, the numbers are not 64 bit integer, they are double precision 
floats, except for the colours that are in single precision during the 
calculations.


Post a reply to this message

From: Thomas de Groot
Subject: Re: HDRI starfield
Date: 29 Jan 2021 02:33:51
Message: <6013ba5f$1@news.povray.org>
Op 26/01/2021 om 00:03 schreef Mike Horvath:
> On 1/25/2021 12:19 PM, Robert McGregor wrote:
>> Mike Horvath <mik### [at] gmailcom> wrote:
>>> Can anyone recommend an HDRI starfield texture that works with POV-Ray?
>>> I haven't used HDRI ever before so I don't know what to look for. 
>>> Thanks!
>>

Retrospectively, after answering to Hj. Malthaner in p.b.i. ("The 
Expanse" Fanart, WIP - Ship passing a ringgateintotheringspace) I 
thought that you could use any deep space photograph from the net (NASA 
has some stunning ones) and convert it to .hdr or .exr. Gimp or (even 
better) IC from Lilysoft can do that. However, you will also need to 
convert to a spherical projection. IC can do some 3d projections but not 
sure about those in this context.

-- 
Thomas


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.