On 2021-08-06 9:16 AM (-4), Chris R wrote:
> clipka <ano### [at] anonymousorg> wrote:
>> Am 05.08.2021 um 22:43 schrieb Chris R:
>>
>>> The pool table is a bit too shiny, but I like the reflection of the store across
>>> the street.
>>
>> It looks to me like you're not using `fresnel`.
>>
>> [snip]
>
> Thanks for the suggestion. I think I have only used fresnel on transparent
> surfaces before, and probably only because I copied a standard material or one
> from an example. (The window doesn't have it turned on either, because I am
> just using M_Glass from textures.inc). I'll try that out.
Fresnel is the way to go whenever you have a non-metallic 'reflection'.
POV-Ray 3.8's finish-level Fresnel is best, but your image appears to
have been rendered with POV-Ray 3.7.
In 3.7, I use a layered texture for opaque objects. The first layer is
opaque with no specular reflection, and the second layer is a clear rgbf
1 pigment with Fresnel reflection in the finish. The result is
comparable to finish-level Fresnel reflection.
The attached images were rendered with POV-Ray 3.7. I didn't have a
ready-made store front, but the sky and railings show well in the
reflections. Notice the differences on the top surfaces of the boxes.
Here are the materials used:
// Left: constant reflection
material
{ texture
{ pigment { red 1 }
finish
{ reflection { 0.05 }
specular albedo 0.05
roughness 0.001
}
}
}
// Center: reflection-level Fresnel
material
{ texture
{ pigment { red 1 }
finish
{ reflection { 1 fresnel } conserve_energy
specular albedo 0.05
roughness 0.001
}
}
interior { ior 1.5 }
}
// Right: layered texture
material
{ texture
{ pigment { red 1 }
}
texture
{ pigment { rgbf 1 }
finish
{ reflection { 1 fresnel } conserve_energy
specular albedo 0.05
roughness 0.001
}
}
interior { ior 1.5 }
}
Post a reply to this message
Attachments:
Download 'fresnel37-above.jpg' (46 KB)
Download 'fresnel37-level.jpg' (41 KB)
Preview of image 'fresnel37-above.jpg'
Preview of image 'fresnel37-level.jpg'
|