|
|
"Dave Blandston" <nomail@nomail> wrote:
> Sir, that is a very intriguing creation. Would you be willing to share that
> delightful green texture?
>
> Kind regards,
> Dave Blandston
Hi Dave,
I like his material too - like many other materials he made.
In the case Robert misses your post, look at the page for the original Povcomp
entry - here he describes the making of the texture
(http://www.povcomp.com/entries/137.php).
Based on his description, I constructed this material -
#declare p_map_metal = pigment {image_map {jpeg "colorful_pattern" gamma 2.2
map_type 0} scale 0.5}
#declare p_map_metal2 =
pigment {
average
turbulence 1
pigment_map {
[1 p_map_metal rotate 90*x]
[1 p_map_metal rotate 90*y]
[1 p_map_metal rotate 90*z]
}
}
#declare fnPig = function {pigment {p_map_metal2}}
#declare N_Hammered =
normal {
bozo
normal_map {
[0 dents 0.05 scale 0.01]
[0.15 dents 0.05 scale 0.001]
[0.3 dents 300 scale 0.0005]
[0.45 dents 0.02 scale 0.01]
[0.5 bumps 0.07 scale 0.01]
[1 dents 0.05 scale 0.005]
}
}
#declare T1 =
material {
texture {
pigment {p_map_metal2}
normal {
average
normal_map {
[1 function {fnPig (x,y,z).gray} bump_size 1 accuracy 0.001]
[0.2 granite 0.5 scale 0.2 accuracy 0.001]
[0.2 granite 0.75 scale 0.12 accuracy 0.001]
[1 N_Hammered bump_size 1 accuracy 0.001]
}
}
finish {
diffuse 0.5
specular 1
roughness 0.003
metallic
reflection {0.4, 1 metallic fresnel on}
conserve_energy
brilliance 8
}
}
interior {ior 1.43}
}
Norbert
Post a reply to this message
|
|