|
|
"MichaelJF" <mi-### [at] t-onlinede> wrote:
>
> My first thought was to have a bigger container and multiple translated
> densities within the media-statement, but the result was annoying too. A close
> container seems to be necessary. I then merged the Containers and put multiple
> densities inside (translated alike the containing boxes). May be more to the
> intent of omniverse - and no scaling needed.
>
I ran MichaelJF's code example with one of the latest 64-bit 3.7.1 dev builds
(v3.7.1-alpha.8927145+av352), with and without the enclosing hollow box.
Without the box, I see NO speckles at all, even during an animation with the
camear moving around. *With* the enclosing box, the speckles appear, as noted.
But I tried something else-- eliminating that hollow box, and substituting a
simple thin background box *behind* the scene instead-- just as a large
background object. With that box in the scene, the speckles are still there. But
*without* the box, no speckles. (I actually animated the box to get smaller--
and as the edges of the box 'pass' the individual speckles (from the camera's
view), they disappear one by one.)
From this simple test, it *seems* that the speckles only appear when there is
some kind of background surface behind the scene's media containers. I don't
know if this helps with the problem, but it's interesting.
By the way: In one of the code examples in this post, the camera is like this:
camera {
location -4*x look_at 0
up y
right image_width/image_height*z // z instead of x
}
I assumed this was just another way of expressing 'handed-ness' in POV-Ray; but
the results (compared to *x) are not what I expected; it actually creates a
flipped mirror-image of the scene, left-to-right. (I tried this with a 'text'
object, and the text is 'backwards.') I've never used *z there before, so I
really don't know the reason for this.
But here's the test scene, re-done, to show the speckles problem. Either run a
150-frame animation (clock 0 to 1), or just eliminate the background box, to see
the difference.
-----------
#version 3.7; // or 3.71
camera {
location -4*x look_at 0
up y
right image_width/image_height*z // should be *x
}
// background box
box{<0,-12 + 11.5*clock,-12 + 11.5*clock>,<.1,12 - 11.5*clock,12 -11.5*clock>
translate 20*x
texture{pigment{rgb .03} finish{ambient 1 diffuse 0}}}
#declare Media_Cont = merge {
#for(It,0,1,1) // create multiple boxes
box { -1,1
rotate <30,30,30>*It
translate -<1,1,1>*It/2+<1,1,1>*It/2
}
#end
hollow on
}
object { Media_Cont
pigment {
rgbt 1
}
interior {
media {
emission <0.1,0.1,0.8>
#for(It,0,1,1) // create multiple densities according to the boxes
density {
boxed
density_map {
[0 rgb 1] [0.1 rgb 0] [1 rgb 0]
}
rotate <30,30,30>*It // same transforms as for the
// merged boxes above
translate -<1,1,1>*It/2+<1,1,1>*It/2
}
#end
}
}
}
// text objects to show the 'mirror-image' behavior of the
// camera as-is
text {
ttf "timrom.ttf" "POV-Ray" .01, 0
texture{pigment {rgb <.4,1,.4>} finish{ambient 1 diffuse 0}}
rotate 90*x
translate -1.8*y
}
text {
ttf "timrom.ttf" "POV-Ray" .01, 0
texture{pigment {rgb <1,.4,.4>} finish{ambient 1 diffuse 0}}
rotate 90*x
translate -1.8*y
translate 1.5*z
}
Post a reply to this message
|
|