clipka <ano### [at] anonymousorg> wrote:
> ... maybe interesting for people who like to toy around with subsurface
> light transport, so I thought I'd share:
>
> https://youtu.be/ClmtcwfWI6M

Definitely one of those refractive plays on light, can be seen to occur even
without the foil added. So probably a slight air gap does same.

Recreate using SSLT? Simple enough, right? Maybe not. I tried animation frames
to look for good values of translucency and mm_per_unit.

Only able to determine a very low mm_per_unit is needed, along with high
translucency "color". At least without trying extreme numbers or changing object
sizes (only a pair of boxes 1 unit thick).

My test object blocks use pigment {rgb 1}, and a gap between them to sandwich
the pseudo foil sheet (no reflection, dark gray, yet specular highlighted).

You will probably want to pause this very short animation near the beginning to
see where it looks best, most closely matching the real video wax
brighter/darker. Light source is above, room being darker near bottom.

/* testing for correct wax SSLT properties */
//cmd:-kfi1 -kff50 -sf8 -ef8

#version 3.7;

#declare MM=25.4*clock;//4;
#declare ST=2-2*clock;//1.5;

global_settings{assumed_gamma 1.0
 subsurface{samples 200,50} mm_per_unit MM}

light_source{-z*99,1 rotate <60,-15,0>}

camera{location -z*9 look_at -y/2 angle 50
 rotate <30,30,0>}

sphere{0,1 pigment{function{abs(y)} // room
 color_map{[0 rgb 0][1 rgb 1]} scale 2 translate -y}
 scale 111}

box{-1,1 hollow scale <2,0.5,1> translate y*0.511
 // upper wax block
 pigment{rgb 1} finish{diffuse 0.5 specular 0.5
 subsurface{translucency ST}}
 interior{ior 1.4}}

box{-1,1 hollow scale <1.95,0.01,0.95>
 // foil sheet between wax blocks
 pigment{rgb 1} finish{diffuse 0.1 specular 0.9 roughness 0.01}}

box{-1,1 hollow scale <2,0.5,1> translate -y*0.511
 // lower wax block
 pigment{rgb 1} finish{diffuse 0.5 specular 0.5
 subsurface{translucency ST}}
 interior{ior 1.445}}

text{ttf "times", concat(str(MM,-2,1)," mm per unit"),0.1,0
 pigment {rgb <0.4,0.8,1>}
 scale <0.75,0.75,0.75>
 rotate <30,30,0>
 translate <-2.25,-2.5,-1>
}

text{ttf "times", concat(str(ST,-2,1)," translucency"),0.1,0
 no_shadow
 pigment {rgb <1,0.4,0.2>}
 scale <0.5,0.5,0.5>
 rotate <30,30,0>
 translate <-3,2.75,-1>
}

Post a reply to this message

Attachments:
Download 'wax_mm_ss.mp4.mpg' (128 KB)