Hello folks,

I have modified the cinematic-like explosiong file posted by H.E. Day at 
p.b.sf

The original file was intended for Megapov 0.4, and I have made a few 
changes to try to render it with MegaPov 1.1. Here is the modified version:

$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$ BEGIN FILE $$$$$$$$$$$$$$$$$$$$$$$$$$$$$

/*
Real Explosion Ver .5
Created by H.E. Day
mailto: Pov### [at] aolcom
This is a demonstation of the explosion.  I will add more features
and functions soetine in the future. Feel free to use this version
in any pic or anim as long as you give me credit for the explosion.

I recommend that you render this with 60 frames or more. Happy destruction!

*/


#version unofficial MegaPov 1.10;
#include "pprocess.inc"

global_settings {
post_process {soft_glow{.675, 2}}
}



#declare Rand = -18
#declare Deform = 1
#declare Detail = .05  //.001 - .1 are good values.
#declare Smoke =  on    //turns the light-sampling smoke on or off
#declare SmokeAmount = 1.25    //.5 is about minimum
#declare SmokeGlowAmount = 1/2
#declare FireBrightness = 1  //.5 is about minimum
#declare FireRedness = 1/2
#declare SmokeBrightness = 1 //.5 is about minimum
#declare SmokeDrift = off //Will the smoke drift?  Any wind?

#declare SmokeDriftDirection = y //doesn't matter if not using SmokeDrift
#declare SmokeDriftAmount = 1 //doesn't matter if not using SmokeDrift






#declare ModClock = pow(clock,.5)

#if (SmokeDrift = off)
#declare SmokeTranslate = vrotate(ModClock/2*y,Rand-90)
#declare SmallSmokeTranslate = vrotate(ModClock/4*y,7*Rand)
#else
#declare SmokeTranslate = ModClock*SmokeDriftDirection*SmokeDriftAmount
#declare SmallSmokeTranslate = 
ModClock*(SmokeDriftDirection/2)*SmokeDriftAmount
#end



#declare Base=function {"sphere",<1>}
#declare Add1=
function {
pigment {granite
color_map {[0 rgb 1][1 rgb 0]}
scale 3
translate 2*ModClock
warp {turbulence 1 omega 0}
translate -2*ModClock
translate Rand
translate SmokeTranslate


}
}
#declare Add3=
function {
pigment {granite
color_map {[0 rgb 0][1 rgb 1]}
scale 4
translate 2*ModClock
warp {turbulence 1 omega 0}
translate -2*ModClock
translate Rand
translate SmokeTranslate
}
}



#declare Add2=
function {
pigment {granite
color_map {[0 rgb 1][1 rgb 0]}
scale 1/4
translate 1*ModClock
warp {turbulence 1 omega 0}
translate -1*ModClock
translate Rand
translate SmallSmokeTranslate

}
}



isosurface {
function {
Base(x,y,z)
+(Add1(y,z,x))*(.65*Deform-(clock*.15*Deform))
+(Add2(y,z,x))*(.15*Deform-(clock*.05*Deform))
}
eval
accuracy Detail
contained_by{sphere{0,1}}
texture {
pigment {
granite
color_map {[.3+.7*clock rgb 
SmokeBrightness-(sin((clock-.25)*2*pi)/2+.5)/2 transmit 
2*clock-1][.7+.3*(2*clock-1) rgb SmokeBrightness-sin(clock * 2 * pi)/2 
transmit pow(clock,.75)/2]}
scale 1/2
translate 2*ModClock
warp {turbulence 1 omega 0}
translate -2*ModClock
translate Rand
translate SmokeTranslate
}
normal {bumps scale .125/3 turbulence .5 bump_size .45*clock}
#if (Smoke = on)
finish {ambient 1/2-clock/2 diffuse 1-clock }
#else
finish {ambient 0 diffuse 0 }
#end
}
texture {
pigment {spherical color_map {
[.15*(1-SmokeGlowAmount) rgbt <1,1/2*(1-FireRedness),0,1>*FireBrightness]
[.4 rgbt <1,1/2*(1-FireRedness),0,.5>*FireBrightness]
[.575 rgb <1,.75-(.5*ModClock)*FireRedness,.1>*1.5*FireBrightness]
[1 rgb 1]


}scale 10 warp {turbulence 1 omega .125} scale 1/10  turbulence .35}
finish {ambient 1}
scale (1.5-(clock*1.5)*(SmokeAmount/2+1/2))*1.45
}


hollow on
scale 1/2+ModClock*3/2
}


camera {
direction 1
location <0,0,2>*2
look_at <0,0,0>
}

light_source {<75,20,0>*100 rgb 1}


sphere {0,1/3 pigment { rgb 1}}

$$$$$$$$$$$$$$$$$$$$$ END FILE $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

and this is the error I am getting:

File Context (5 lines)
#include "pprocess.inc"
global_settings {
post_process {soft_glow{
Parse Error: expected 'operand', found { instead

I have looked at the post_process syntax and I can't find where the 
parse error is.

Can anyone help me figure out where the error is?

Thanks in advance

Fidel.

Post a reply to this message

"Fidel Viegas" <non### [at] nodomaincom> wrote in message
news:42b682c0@news.povray.org...
> Hello folks,
>
> I have modified the cinematic-like explosiong file posted by H.E. Day at
> p.b.sf
>
> The original file was intended for Megapov 0.4, and I have made a few
> changes to try to render it with MegaPov 1.1. Here is the modified version:
>
<...>
> and this is the error I am getting:
>
> File Context (5 lines)
> #include "pprocess.inc"
> global_settings {
> post_process {soft_glow{
> Parse Error: expected 'operand', found { instead
>
> I have looked at the post_process syntax and I can't find where the
> parse error is.
>
> Can anyone help me figure out where the error is?

The problem is that the post-processing feature of MegaPov 1.1 (or higher) is
completely different (more powerful, but sadly enough also a lot slower) than it
was in MegaPov 0.4.  Remove the post-process block, and it should work fine.  If
you want the soft-glowing post-processing, you'll need to make it yourself,
because, as far as I know, it's not included with MegaPov 1.1.  It's not that
hard to do, but as I said earlier, it's rather slow.

cu!
--
camera{location-z*3}#macro G(b,e)b+(e-b)*(C/50)#end#macro L(b,e,k,l)#local C=0
;#while(C<50)sphere{G(b,e),.1pigment{rgb G(k,l)}finish{ambient 1}}#local C=C+1
;#end#end L(y-x,y,x,x+y)L(y,-x-y,x+y,y)L(-x-y,-y,y,y+z)L(-y,y,y+z,x+y)L(0,x+y,
<.5,1,.5>,x)L(0,x-y,<.5,1,.5>,x)                 // ZK http://www.povplace.com

Post a reply to this message

Fidel Viegas wrote:
> Hello folks,
> 
> I have modified the cinematic-like explosiong file posted by H.E. Day at 
> p.b.sf
> 
> The original file was intended for Megapov 0.4, and I have made a few 
> changes to try to render it with MegaPov 1.1. Here is the modified version:
> 
> [...]
> #version unofficial MegaPov 1.10;
> #include "pprocess.inc"
> 
> global_settings {
> post_process {soft_glow{.675, 2}}
> }
>

This isn't valid MegaPOV 1.x syntax - see

http://megapov.inetart.net/manual-1.2/inc_pprocess.inc.html#post_proc_macros

for how to use it.  Note however that there isn't any 'soft glow' filter 
implemented at the moment.

Christoph

-- 
POV-Ray tutorials, include files, Sim-POV,
HCR-Edit and more: http://www.tu-bs.de/~y0013390/
Last updated 03 May. 2005 _____./\/^>_*_<^\/\.______

Post a reply to this message

Thanks a lot guys!

I'll try to play with it.

Fidel.

Post a reply to this message