 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Someone asked me to post this. It's the earth.inc file that I use to create
the images of Earth that are on my website (http://www.scottgammans.com).
// earth.inc by Scott Gammans http://www.scottgammans.com
// This file uses three images of the earth, all mercator projections:
// (1) earth_landmask_mercator.tif - black & white landmask where
// water is black and land is white
// (2) earth_truecolor_mercator.tif - truecolor image of earth
// (3) earth_clouds_mercator.tif - black & white cloud layer image
// All of these files can be obtained at NASA's Visible Earth website
// http://visibleearth.nasa.gov/
#declare EARTH_RADIUS=3963;
// Example usage: object {Earth(0,true,true,true,1.0)}
// where
// axial_rot = Earth's axial rotation in degrees
// use_spec = if true, use specular water feature
// use_clouds = if true, use cloud layer
// use_diff = if true, use atmospheric diffusion
// diff_adj = should normally be 1.0. Amts above/below 1
// thicken/reduce the blue ring of diffusion
// around planet. Useful for when rendering a
// small image and you want the ring to show up
#macro Earth(axial_rot,use_spec,use_clouds,use_diff,diff_adj)
union {
// The base planet:
sphere {0,EARTH_RADIUS
texture {
#if (use_spec=true)
// This image file is a two-color mercator-projection image
of
// the Earth where the water is black and the land is white
image_pattern {tiff "earth_landmask_mercator.tif" map_type 1}
texture_map {
// This is a true-color mercator image of the Earth
[0.0000 pigment{
image_map {
tiff "earth_truecolor_mercator.tif"
map_type 1
}
}
finish {
ambient 0.0
specular 0.10 // 0.0
reflection {0.05,0.25} //
roughness 0.10 // 0.05
diffuse 0.85 // 0.6
brilliance 1 // 1.0
phong 0.025 // 0.0
phong_size 75 // 40 < less glossy
}
]
// This is a true-color mercator image of the Earth
[1.0000 pigment{
image_map {
tiff "earth_truecolor_mercator.tif"
map_type 1
}
}
finish {ambient 0}
]
}
scale EARTH_RADIUS
#else
// This is a true-color mercator image of the Earth
pigment{image_map {tiff "earth_truecolor_mercator.tif"
map_type 1}}
finish {ambient 0.0}
#end
}
}
// The cloud layer:
#if (use_clouds=true)
difference {
sphere {0,EARTH_RADIUS*1.0002}
sphere {0,EARTH_RADIUS*1.0001}
texture {
pigment {
// This is a two-color mercator image of Earth's cloud
layer
image_pattern {tiff "earth_clouds_mercator.tif" map_type 1}
color_map {
[0.00 color rgbt <1,1,1,1>]
[1.00 color rgbt <1,1,1,0>]
}
}
finish {ambient 0.0}
}
}
#end
// The diffusion of sunlight in the atmosphere:
#if (use_diff=true)
difference{
sphere {0,EARTH_RADIUS*1.0037*diff_adj}
sphere {0,EARTH_RADIUS*1.0003}
hollow
material {
texture {
pigment {rgbf 1}
finish {ambient 0.0}
}
interior{
media {
scattering {4, <0.0005,0.0005,0.001>}
intervals 1
}
}
}
}
#end
rotate y*axial_rot
rotate x*-23.4
}
#end
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
// All of these files can be obtained at NASA's Visible Earth website
// http://visibleearth.nasa.gov/
Where on the site? Searches for the file names and even the term mercator
all come up empty.
Jim
"Scott Gammans" <deepgloathatesspamaatyahoodotcom> wrote in message
news:web.3fbd42078ae459e44e0a58990@news.povray.org...
> Someone asked me to post this. It's the earth.inc file that I use to
create
> the images of Earth that are on my website (http://www.scottgammans.com).
>
> // earth.inc by Scott Gammans http://www.scottgammans.com
>
> // This file uses three images of the earth, all mercator projections:
> // (1) earth_landmask_mercator.tif - black & white landmask where
> // water is black and land is white
> // (2) earth_truecolor_mercator.tif - truecolor image of earth
> // (3) earth_clouds_mercator.tif - black & white cloud layer image
> // All of these files can be obtained at NASA's Visible Earth website
> // http://visibleearth.nasa.gov/
>
> #declare EARTH_RADIUS=3963;
>
> // Example usage: object {Earth(0,true,true,true,1.0)}
> // where
> // axial_rot = Earth's axial rotation in degrees
> // use_spec = if true, use specular water feature
> // use_clouds = if true, use cloud layer
> // use_diff = if true, use atmospheric diffusion
> // diff_adj = should normally be 1.0. Amts above/below 1
> // thicken/reduce the blue ring of diffusion
> // around planet. Useful for when rendering a
> // small image and you want the ring to show up
> #macro Earth(axial_rot,use_spec,use_clouds,use_diff,diff_adj)
> union {
>
> // The base planet:
> sphere {0,EARTH_RADIUS
> texture {
> #if (use_spec=true)
> // This image file is a two-color mercator-projection
image
> of
> // the Earth where the water is black and the land is
white
> image_pattern {tiff "earth_landmask_mercator.tif" map_type 1}
> texture_map {
> // This is a true-color mercator image of the Earth
> [0.0000 pigment{
> image_map {
> tiff "earth_truecolor_mercator.tif"
> map_type 1
> }
> }
> finish {
> ambient 0.0
> specular 0.10 // 0.0
> reflection {0.05,0.25} //
> roughness 0.10 // 0.05
> diffuse 0.85 // 0.6
> brilliance 1 // 1.0
> phong 0.025 // 0.0
> phong_size 75 // 40 < less glossy
> }
> ]
> // This is a true-color mercator image of the Earth
> [1.0000 pigment{
> image_map {
> tiff "earth_truecolor_mercator.tif"
> map_type 1
> }
> }
> finish {ambient 0}
> ]
> }
> scale EARTH_RADIUS
> #else
> // This is a true-color mercator image of the Earth
> pigment{image_map {tiff "earth_truecolor_mercator.tif"
> map_type 1}}
> finish {ambient 0.0}
> #end
> }
> }
>
> // The cloud layer:
> #if (use_clouds=true)
> difference {
> sphere {0,EARTH_RADIUS*1.0002}
> sphere {0,EARTH_RADIUS*1.0001}
> texture {
> pigment {
> // This is a two-color mercator image of Earth's cloud
> layer
> image_pattern {tiff "earth_clouds_mercator.tif" map_type 1}
> color_map {
> [0.00 color rgbt <1,1,1,1>]
> [1.00 color rgbt <1,1,1,0>]
> }
> }
> finish {ambient 0.0}
> }
> }
> #end
>
> // The diffusion of sunlight in the atmosphere:
> #if (use_diff=true)
> difference{
> sphere {0,EARTH_RADIUS*1.0037*diff_adj}
> sphere {0,EARTH_RADIUS*1.0003}
>
> hollow
> material {
> texture {
> pigment {rgbf 1}
> finish {ambient 0.0}
> }
>
> interior{
> media {
> scattering {4, <0.0005,0.0005,0.001>}
> intervals 1
>
> }
> }
> }
> }
> #end
>
> rotate y*axial_rot
> rotate x*-23.4
> }
> #end
>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Whoops... wrong URL. Although all of the files *are* at NASA's Visible Earth
website, the master webpage that organizes the mercator projections you
want is located at
http://earthobservatory.nasa.gov/Newsroom/BlueMarble/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thanks for the update. However, the naming convention used at the NASA site
differ from yours. Am I correct in assuming the following:
What you call "earth_clouds_mercator.tif " is the same as what NASA calls
"cloud_combined_2048.tiff"?
What you call "earth_truecolor_mercator.tif " is the same as what NASA calls
"land_ocean_ice_2048.tiff"?
Where is the file you call "earth_landmask_mercator.tif"?
Thanks again.
Jim
"Scott Gammans" <deepgloathatesspamaatyahoodotcom> wrote in message
news:web.3fc1293265df8252cbec1f9c0@news.povray.org...
> Whoops... wrong URL. Although all of the files *are* at NASA's Visible
Earth
> website, the master webpage that organizes the mercator projections you
> want is located at
>
> http://earthobservatory.nasa.gov/Newsroom/BlueMarble/
>
>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Your guesses are correct; I did rename the NASA files to make them easier to
find on my workstation. Shoulda mentioned that in the posting above, huh?
:)
I did *not* get the landmask file from NASA's Visible Earth website; I don't
remember where I got it but it wasn't at NASA. You can do what I did and
Google for "earth landmask high resolution" (I think that's how I found it)
or better yet, you can create your own landmask file with any decent photo
editing program and the truecolor TIFF file from NASA's website. How to do
this is left as an exercise for the reader, but what you want to wind up
with is a two-color mercator image of the Earth where the land is white and
the water is black (that way, the texture map applies the specular water
highlights only to the black areas--where the water is).
One final note--there are many ways that my Earth model could be improved.
The cloud layer is an infinitely thin layer right now with no thickness.
There is no bump map to give land features any visible height (although
honestly, at the distances you'll normally place the camera from the model
you shouldn't see any height anyway--that's why I removed the bump map that
used to be there... the extra CPU cycles didn't produce any visible
difference that I could see). The oceans are a flat blue with no waves
(again, scale issues), and the specular highlights on the water could be
improved.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
OK. Thanks!
Jim
"Scott Gammans" <deepgloathatesspamaatyahoodotcom> wrote in message
news:web.3fc297e265df8252cbec1f9c0@news.povray.org...
> Your guesses are correct; I did rename the NASA files to make them easier
to
> find on my workstation. Shoulda mentioned that in the posting above, huh?
> :)
>
> I did *not* get the landmask file from NASA's Visible Earth website; I
don't
> remember where I got it but it wasn't at NASA. You can do what I did and
> Google for "earth landmask high resolution" (I think that's how I found
it)
> or better yet, you can create your own landmask file with any decent photo
> editing program and the truecolor TIFF file from NASA's website. How to do
> this is left as an exercise for the reader, but what you want to wind up
> with is a two-color mercator image of the Earth where the land is white
and
> the water is black (that way, the texture map applies the specular water
> highlights only to the black areas--where the water is).
>
> One final note--there are many ways that my Earth model could be improved.
> The cloud layer is an infinitely thin layer right now with no thickness.
> There is no bump map to give land features any visible height (although
> honestly, at the distances you'll normally place the camera from the model
> you shouldn't see any height anyway--that's why I removed the bump map
that
> used to be there... the extra CPU cycles didn't produce any visible
> difference that I could see). The oceans are a flat blue with no waves
> (again, scale issues), and the specular highlights on the water could be
> improved.
>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Mon, 24 Nov 2003 18:50:42 EST, "Scott Gammans"
<deepgloathatesspamaatyahoodotcom> wrote:
>I did *not* get the landmask file from NASA's Visible Earth website; I don't
>remember where I got it but it wasn't at NASA. You can do what I did and
>Google for "earth landmask high resolution" (I think that's how I found it)
>or better yet, you can create your own landmask file with any decent photo
>editing program and the truecolor TIFF file from NASA's website. How to do
>this is left as an exercise for the reader,
The (8192w x 4096h), 31.81 MB TIFF file you find at
http://visibleearth.nasa.gov/cgi-bin/viewrecord?11612
contains a landmask as a separate channel...
--
Erhard Ducke
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Scott Gammans" <deepgloathatesspamaatyahoodotcom> wrote in message
news:web.3fc297e265df8252cbec1f9c0@news.povray.org...
> I did *not* get the landmask file from NASA's Visible Earth website;
I don't
> remember where I got it but it wasn't at NASA.
Maybe here?
http://members.shaw.ca/evildrganymede/art/planets/earth.htm
~Steve~
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
