This is source for the image 'Energy Ball' posted in p.b.i

--8<-------------------------------

#version 3.5;

// +A0.1 +AM2
// -F +W1024 +H768 +A0.1 +AM2

global_settings {
	assumed_gamma 2
	photons {
		count 750000
		jitter 0
	}
}

#declare cam1 = camera {
	location	<-1,10,-2>
	look_at		<0,0,0>
}

#declare cam2 = camera {
	location	<0,4,0>
	look_at		<0,0,0>
}

camera { cam2 }

// fill lights
//light_source { <100,100,100> color rgb 1 shadowless }
//light_source { <-100,100,-100> color rgb 1 shadowless }

// refracted spotlight
light_source {
	<0,10,0>
	color rgb <1,1,1>
	spotlight radius 0 falloff 10
	point_at <0,5,0>
	
	photons {
		reflection off
		refraction on
	}
}

// refraction object
box {
	<-1,0,-1>, <1,0.5,1>
	pigment { color rgb 1 filter 1 }
	translate y*5

	interior {
		ior 1.5
		dispersion 5
		dispersion_samples 18
	}

	// this is the fun part, scattering the light
	normal { bumps 0.1 scale 0.1 }
	
	photons {
		target
		collect off
		reflection off
		refraction on
	}
}


// projection 'screen'
plane {
	y,0
	
	pigment { color rgb 1 }

	finish { ambient 0 diffuse 1 }

	photons {
		collect on
		reflection off
		refraction off
	}
}

Post a reply to this message