POV-Ray : Newsgroups : povray.text.scene-files : Egg macros Server Time
28 Mar 2024 06:22:42 EDT (-0400)
  Egg macros (Message 1 to 5 of 5)  
From: Thomas de Groot
Subject: Egg macros
Date: 7 May 2017 03:11:26
Message: <590ec89e$1@news.povray.org>
See the Egg message in p.b.i.

These are the major macros used for the translucent objects there (you 
may have to do some editing; dragon not included):

//==========================================================Marble cube
#macro JH_Marble (Detail, SS, Translucency) //James Holsenback
material {
   texture {
     #if (Detail)
       pigment {
         marble
         scale 0.5
         turbulence 1 lambda 3
         color_map {
           [0 srgb <0.9570, 0.9570, 0.8594>]
           [1 srgb <0.9570, 0.9570, 0.8594>/2]
         }
       }
       finish {
         specular 0.15
         roughness 1e-1
         #if (SS)
           subsurface {translucency Translucency}
         #end
         reflection { 0.2 fresnel }
         conserve_energy
       }
       normal{
         marble
         scale 0.5
         turbulence 1 lambda 3
       }
     #else
       pigment {srgb 1}
     #end
   }
   interior {ior 1.5}
}
#end

#declare Detail = on; //for JH_Marble only
#declare SS = on;
#declare Translucency = <0.45, 0.38, 0.33>*5;

superellipsoid {
   <0.15, 0.15>
   JH_Marble (Detail, SS, Translucency)
   scale <1, 1, 1>
   rotate <0, -20, 0>
   translate <0, 0, 0>
}

//==========================================================Dragon
#macro TdG_Celadon (SScel, TranslucencyCeladon)
material {
   texture {
     pigment {
       bozo
       pigment_map {
         [0.0 color srgb <0.762025, 0.883775, 0.762025>]
         [0.2 color srgb <0.855688, 0.935979, 0.855688>]
         [0.5 color srgb <0.728519, 0.896481, 0.728519>]
         [0.8 color srgb <0.937467, 1.000000, 0.937467>]
         [1.0 color srgb <0.548054, 0.722746, 0.548054>]
       }
     }
     normal {
       crackle 0.5 solid
       warp {turbulence <0.1, 0.1, 0.1>}
       scale  0.1
     }
     finish {
       diffuse 0.6
       specular 0.5
       roughness 0.005
       conserve_energy
       #if (SScel)
         subsurface {translucency TranslucencyCeladon}
       #end
       reflection {
         0.01 , 0.2
         fresnel  on
         falloff  1.0
         exponent 1.0
       }
     }
   }
   interior {ior 1.5}
}
#end

#include "xyzrgb_dragon90k_POV_geom.inc" //dragon or any other obejct

#declare Dragon =
object {xyzrgb_dragon90k_
   translate 41.2849*y
   scale <1, 1, 1>*0.01
}

#declare SScel = on;
#declare TranslucencyCeladon = <0.728519, 0.896481, 0.728519>*0.5; 
//one of the celadon pigments

object {Dragon
   TdG_Celadon(SScel, TranslucencyCeladon)
   rotate <0, 0, 0>
   translate <0, 1, 0>
}

//=========================================================blackbird egg
#macro TdG_Blackbird_Eggshell (SSegg, TranslucencyEgg)
material {
   texture {
     pigment {
       granite
       pigment_map {
         [0.75 srgb <0.80, 0.92, 1.00>]
         [0.85 srgb <0.50, 0.40, 0.30>]
       }
       scale 0.125
     }
     normal { bumps 0.095 scale 0.008 }
     finish {
       ambient 0.01
       diffuse albedo 0.7
       specular albedo 0.05
       roughness 0.005
       fresnel
       #if (SSegg)
         subsurface {translucency TranslucencyEgg}
       #end
       reflection {0.01, 0.20 fresnel roughness 0.005}
       conserve_energy
     }
   }
   interior {ior 1.5}
}
#end

//blackbird egg
#declare Egg =
ovus {
   1.00, 0.65 // base_radius, top_radius  with: top_radius< base_radius!
   rotate 80*x  //put egg on its side
   translate <0.00, 1.00, 0.00> //origin at base
   scale 0.25
}

#declare SSegg= on;
#declare TranslucencyEgg = <1.00, 0.92, 0.80>*(5*0.25); //one of the 
shell pigments, reversed

object {Egg
   TdG_Blackbird_Eggshell (SSegg, TranslucencyEgg)
   rotate 110*y
   translate <-0.50, 1, -0.50>
   rotate -10*y
}


-- 
Thomas


Post a reply to this message

From: Cousin Ricky
Subject: Re: Egg macros
Date: 8 May 2017 17:57:00
Message: <5910e9ac$1@news.povray.org>
On 2017-05-07 03:11 AM (-4), Thomas de Groot wrote:
> #macro JH_Marble (Detail, SS, Translucency) //James Holsenback

How did you find that fantastic marble texture?  Does Jim have a 
repository somewhere?


Post a reply to this message

From: Thomas de Groot
Subject: Re: Egg macros
Date: 10 May 2017 03:00:07
Message: <5912ba77$1@news.povray.org>
On 8-5-2017 23:56, Cousin Ricky wrote:
> On 2017-05-07 03:11 AM (-4), Thomas de Groot wrote:
>> #macro JH_Marble (Detail, SS, Translucency) //James Holsenback
>
> How did you find that fantastic marble texture?  Does Jim have a
> repository somewhere?
>
>

I don't remember, I am afraid. I probably picked it up in one of his 
messages.... yes, I see that I joted down: "p.b.i. Paradise; 12-2-2014"

-- 
Thomas


Post a reply to this message

From: omniverse
Subject: Re: Egg macros
Date: 10 May 2017 04:50:00
Message: <web.5912d39b6c350ffb9c5d6c810@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> See the Egg message in p.b.i.

Thanks for showing both render and scene file! Cool stuff.

Bob


Post a reply to this message

From: Jim Holsenback
Subject: Re: Egg macros
Date: 10 May 2017 07:48:25
Message: <5912fe09@news.povray.org>
On 5/10/2017 3:00 AM, Thomas de Groot wrote:
> On 8-5-2017 23:56, Cousin Ricky wrote:
>> On 2017-05-07 03:11 AM (-4), Thomas de Groot wrote:
>>> #macro JH_Marble (Detail, SS, Translucency) //James Holsenback
>>
>> How did you find that fantastic marble texture?  Does Jim have a
>> repository somewhere?

nope i don't ... not public anyways

>>
>>
> 
> I don't remember, I am afraid. I probably picked it up in one of his 
> messages.... yes, I see that I joted down: "p.b.i. Paradise; 12-2-2014"

couldn't remember exactly either until seeing this and then only vaguely 
... for some reason i keep thinking pair of dice!


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.