-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

This is the scene file for the images in the thread entitles "Oh
dear" on povray.binaries.images. Enjoy!

Andrew.

*****LoveNBubbles1-Red.pov*****
global_settings
{
  noise_generator 3
  max_trace_level 10
}

camera
{
  location <0, 0, -500>
  direction z
  look_at <0, 0, 0>
}


light_source {<   0, -900,    0>, colour rgb <1, 0.2, 0>}

// Text
light_group
{
  light_source {<-200, +300, -300>, colour rgb 1}

  object
  {
    union
    {
      object
      {
        text {ttf "timrom.ttf" "Love" 0.5 0}
        scale 150
        translate <-300, +100, 0>
      }
      object
      {
        text {ttf "timrom.ttf" "&" 0.5 0}
        scale 150
        translate <-50, -50, 0>
      }
      object
      {
        text {ttf "timrom.ttf" "Bubbles" 0.5 0}
        scale 150
        translate <-200, -200, 0>
      }
    }
    texture
    {
      pigment {colour rgb <1, 0, 0>}
      finish {ambient 0 specular 0.5}
    }
  }

  global_lights off
}

#declare RND = seed(0);

#declare Spread = 500;

// Bubbles
object
{
  union
  {
    #declare lp = 0;
    #while (lp<500)
      #declare X = rand(RND)*2*Spread - Spread;
      #declare Y = rand(RND)*2*Spread - Spread;
      #declare Z = rand(RND)*900 + 20;
      #declare R = rand(RND)*10 + 30;

      sphere {<X, Y, Z>, R}

      #declare lp = lp + 1;
    #end
  }
  texture
  {
    pigment {colour rgbt <0, 0, 0, 1>}
    finish {ambient 0 specular 1 reflection {0, 1} conserve_energy}
  }
  interior {ior 1/1.33}
}

// Background
object
{
  sphere {<0, 0, 0>, 1000} hollow
  //plane {-z, -1000}
  texture
  {
    pigment
    {
      bozo
      colour_map
      {
        [0 colour rgb 0]
        [1 colour rgb 1]
      }
      scale 500
    }
    finish {ambient 1}
  }
}
*****LoveNBubbles.pov*****


-----BEGIN PGP SIGNATURE-----
Version: PGPfreeware 7.0.3 for non-commercial use <http://www.pgp.com>

iQA/AwUBPZHCLbEpzUF0Y1JeEQJQhQCfYOkgxxIEDlc0tidgco1OqchzKCcAni8l
8/KgMTqfi/dHEuchDaKwv8zS
=vVo7
-----END PGP SIGNATURE-----

Post a reply to this message