// Persistence of Vision Ray Tracer Scene Description File
// File: ploughed field.pov
// Date: 00/03/01
// Auth: Mick Hazelgrove

#version unofficial MegaPov 0.7;

#declare Rad_on = 1;
#declare R = seed(4363);

#include "colors.inc"
#include "skies.inc"

global_settings{
  assumed_gamma 1.0
  max_trace_level 10

 #if(Rad_on =1)
   ini_option "+QR"

   radiosity{
     pretrace_start 0.08
  pretrace_end .001
  count 50
  nearest_count  1//5
  error_bound .05
  recursion_limit 1
  low_error_factor .5
  gray_threshold 0
  minimum_reuse 0.015
  brightness 3
  normal on
  //media on
  max_sample 2
  adc_bailout 0.01/1
  }
 #end
}

// ------------------------------------------------

#declare Image_Length = 750;
#declare Image_Height = 450;

camera
{
  location  <0.0, 42.5, -35.0>
  direction 1.5*z
  right Image_Length/Image_Height*x
  look_at   <0.0, 46,  0.0>
}

sky_sphere
{
  pigment
  {
    gradient y turbulence .2
    color_map { [0.0 color rgb <1,.9,.65>  ] [0.8 color
rgb<.7,.8,1> ] }rotate x*15 // <.8,.8,.9>
  }
}

light_source {
 0*x
color rgb <0.9965, 0.875, 0.275>
translate <500,500,-5000>
media_attenuation on
media_interaction on
}

glow{ type 0
 color<1,.8,.5>*3///2
 warp{turbulence .5}
 translate < 0, 40,750>
 }

// -----------------------------------

#declare GMTex = texture{
 pigment{
 agate color_map {
  [0 rgb<1,.5,.3>]
  [0.375 rgb<1,.5,0>]
  [0.5 rgb<1,.3,.2>]
  [1 rgb<1,.375,.1>]
  }
    scale 50
     turbulence 5
   }
 finish { ambient 0.0 diffuse .1 specular .1 roughness .1}

 normal{bozo normal_map{
   [0 crackle 100 sine_wave scale 10]
   [.2 bozo 120 scallop_wave scale 2.5]
   [.9 granite 55 scallop_wave scale 2]
   [1 dents 100 sine_wave]
   }
     turbulence .3
     }
}

#declare FG = function{
      pigment{
       gradient x pigment_map{
         [0 rgb 0]
         [1 rgb .5]
         }
        warp{turbulence .3}//.3
        scale .0075/1.5
        sine_wave
       }//pigment
       }//function
#declare FB = function{
      pigment{
       bozo pigment_map{
         [0 rgb 0]
         [1 rgb .175]//.175
         }
        warp{turbulence 3}
        scale .00075/2
        poly_wave
       }//pigment
       }//function

#declare FD = function{
      pigment{
       dents pigment_map{
         [0 rgb 0]
         [1 rgb .25]//.25
         }
        warp{turbulence 1.5}
        scale .0005/1.75/2
        sine_wave
       }//pigment
       }//function

#declare FGR = function{
      pigment{
       granite pigment_map{
         [0 rgb 0]
         [1 rgb .00275]//.25
         }
        warp{turbulence 5}
        scale .00025/1.75/1.25
        sine_wave
       }//pigment
       }//function

#declare GM =
 height_field {
  //pattern 500, 500 {
   //pattern 3500,3500 {
  //pattern 1000,1000{
  pattern 5000,5000{
   hf_gray_16
     function{
      FG
      +FB
      +FD
      -FGR
      }
    }
    smooth
    translate<-.5,0,0>
    }

object{GM
 scale <100,20,100>
 scale <20,.5,70>
  translate <0.5, 0, -15>
  texture{GMTex}
   }


//----------------------------------------------------------------

Post a reply to this message