/* gamma_disc.pov
 *
 * Based on Christoph Lipka's gamma test scene.
 * http://news.povray.org/povray.general/thread/%3Cweb.4986021ec6af8354f8450bd80%40news.povray.org%3E/
 *
 * Copyright © 2009 Richard Callwood III.  Some rights reserved, under the
 * terms of the Creative Commons GNU General Public License.
 * This software carries no warranty, express or implied.
 * See http://creativecommons.org/licenses/GPL/2.0/ for more information.
 * Created 10-mar-2009
 * Updated 10-mar-2009
 */
//+w400 +h300 +a +am2 +r5 -j +kff10

//Select channel(s), to test colors and evade white point problems
#ifndef (Test) #declare Test = 1; #end
#if (clock_on) #declare Test = frame_number; #end

#include "colors.inc"

global_settings { assumed_gamma 1 } //Do not touch!

#default { finish { ambient 1 diffuse 0 } }

camera
{  orthographic
   location -10 * z
   right max (1, image_width/image_height) * x
   up max (1, image_height/image_width) * y
}

#switch (Test)

   #range (2, 4)
      #declare c_Color1 = rgb 0;
      #declare c_Color2 = rgb CH2RGB ((Test - 2) * 120);
      #break
   
   #range (5, 10)
      #declare c_Color1 = rgb CH2RGB (Test * 60);
      #declare c_Color2 = rgb CH2RGB ((Test - 5) * 60);
      #break

   #else
      #declare c_Color1 = rgb 0;
      #declare c_Color2 = rgb 1;
      #break
#end

sphere { 0, 0.375 pigment { color (c_Color1 + c_Color2) / 2 } }

plane { -z, 0 pigment { checker c_Color1 c_Color2 scale 1/75 } }