#version 3.7;
global_settings { assumed_gamma 1.0 }
#declare Red1 = texture { pigment { color srgb <0.8,0.1,0.1> } } 
#declare Red2 = texture { pigment { color srgb <0.7,0.0,0.0> } } 
#declare White1 = texture { pigment { color srgb <0.8,0.8,0.8> } } 
#default{ texture { Red1 } }

#declare Tex= texture { checker 
texture { White1 }
texture { Red1 }
scale <1/6,1/18,1>
} ;
#declare Low = 0.25+0.25/2-0.25/6;
#declare High = Low+5/18;
#declare Wid= 0.002;
#declare Band = texture { planar 
texture_map {
[Low-Wid  Red1 ]
[Low-Wid White1 ]
[Low White1 ]
[Low Tex ]
[High Tex ]
[High White1 ]
[High+Wid White1 ]
[High+Wid Red1 ]
}
};

#declare Leg = union {
sphere { 17*y, 17  texture { Red2 } }
lemon { 17*y, 18, (95-18)*y,0, 98 }
difference {
disc { <-94, 17, 0>,z, 112 clipped_by { box { <-80,17,1>,< 100,200,-1>}}
}
sphere { <-80,17,0>,80-17 }
}
translate 80*x
}

plane { y, 0 texture { pigment { color rgb 1 } } }
union {
object { Leg }
object { Leg rotate 120*y}
object { Leg rotate -120*y}
lemon { 80*y, 14, 95*4*y, 0, 650 sturm uv_mapping texture { Band } }
rotate -32*y
}

camera { location <-320, 400, -1000>
up y
right image_width/image_height*x
direction z
look_at 200*y
angle 25*image_width/image_height
}

light_source { <-1500, 1000, -3000>, 1 }